blob: 90439940fbf4b4e6f264c2617023f975e7924bf3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
|
/* Excerpts written by Martin Mares <mj@atrey.karlin.mff.cuni.cz> */
/* Modified for i386/x86-64 Xen by Keir Fraser */
/* Modified for ARM Xen by Ian Campbell */
#include <xen/config.h>
#include <xen/cache.h>
#include <asm/page.h>
#include <asm/percpu.h>
#undef ENTRY
#undef ALIGN
ENTRY(start)
#if defined(__arm__)
#define FORMAT arm
#elif defined(__aarch64__)
#define FORMAT aarch64
#endif
OUTPUT_ARCH(FORMAT)
PHDRS
{
text PT_LOAD /* XXX should be AT ( XEN_PHYS_START ) */ ;
}
SECTIONS
{
. = XEN_VIRT_START;
_start = .;
.text : /* XXX should be AT ( XEN_PHYS_START ) */ {
_stext = .; /* Text section */
*(.text)
*(.fixup)
*(.gnu.warning)
_etext = .; /* End of text section */
} :text = 0x9090
. = ALIGN(PAGE_SIZE);
.rodata : {
_srodata = .; /* Read-only data */
*(.rodata)
*(.rodata.*)
_erodata = .; /* End of read-only data */
} :text
.data : { /* Data */
. = ALIGN(PAGE_SIZE);
*(.data.page_aligned)
*(.data)
*(.data.rel)
*(.data.rel.*)
CONSTRUCTORS
} :text
. = ALIGN(SMP_CACHE_BYTES);
.data.read_mostly : {
/* Exception table */
__start___ex_table = .;
*(.ex_table)
__stop___ex_table = .;
/* Pre-exception table */
__start___pre_ex_table = .;
*(.ex_table.pre)
__stop___pre_ex_table = .;
*(.data.read_mostly)
*(.data.rel.ro)
*(.data.rel.ro.*)
} :text
#ifdef LOCK_PROFILE
. = ALIGN(32);
__lock_profile_start = .;
.lockprofile.data : { *(.lockprofile.data) } :text
__lock_profile_end = .;
#endif
. = ALIGN(PAGE_SIZE); /* Init code and data */
__init_begin = .;
.init.text : {
_sinittext = .;
*(.init.text)
_einittext = .;
} :text
. = ALIGN(PAGE_SIZE);
.init.data : {
*(.init.rodata)
*(.init.rodata.str*)
*(.init.data)
*(.init.data.rel)
*(.init.data.rel.*)
. = ALIGN(4);
__CTOR_LIST__ = .;
LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2)
*(.ctors)
LONG(0)
__CTOR_END__ = .;
} :text
. = ALIGN(32);
.init.setup : {
__setup_start = .;
*(.init.setup)
__setup_end = .;
} :text
.initcall.init : {
__initcall_start = .;
*(.initcallpresmp.init)
__presmp_initcall_end = .;
*(.initcall1.init)
__initcall_end = .;
} :text
.xsm_initcall.init : {
__xsm_initcall_start = .;
*(.xsm_initcall.init)
__xsm_initcall_end = .;
} :text
. = ALIGN(STACK_SIZE);
__init_end = .;
.bss : { /* BSS */
__bss_start = .;
*(.bss.stack_aligned)
. = ALIGN(PAGE_SIZE);
*(.bss.page_aligned)
*(.bss)
. = ALIGN(SMP_CACHE_BYTES);
__per_cpu_start = .;
*(.bss.percpu)
. = ALIGN(SMP_CACHE_BYTES);
*(.bss.percpu.read_mostly)
. = ALIGN(SMP_CACHE_BYTES);
__per_cpu_data_end = .;
__bss_end = .;
} :text
_end = . ;
#ifdef CONFIG_DTB_FILE
/* Section for the device tree blob (if any). */
_sdtb = .;
.dtb : { *(.dtb) } :text
#endif
/* Sections to be discarded */
/DISCARD/ : {
*(.exit.text)
*(.exit.data)
*(.exitcall.exit)
*(.eh_frame)
}
/* Stabs debugging sections. */
.stab 0 : { *(.stab) }
.stabstr 0 : { *(.stabstr) }
.stab.excl 0 : { *(.stab.excl) }
.stab.exclstr 0 : { *(.stab.exclstr) }
.stab.index 0 : { *(.stab.index) }
.stab.indexstr 0 : { *(.stab.indexstr) }
.comment 0 : { *(.comment) }
}
|
