fish

13 files changed, 2827 insertions, 0 deletions

diff --git a/grub-core/boot/decompressor/minilib.c b/grub-core/boot/decompressor/minilib.c
new file mode 100644
index 0000000..f2a2ef7
--- /dev/null
+++ b/grub-core/boot/decompressor/minilib.c
@@ -0,0 +1,102 @@
+/*
+ *  GRUB  --  GRand Unified Bootloader
+ *  Copyright (C) 2010  Free Software Foundation, Inc.
+ *
+ *  GRUB is free software: you can redistribute it and/or modify
+ *  it under the terms of the GNU General Public License as published by
+ *  the Free Software Foundation, either version 3 of the License, or
+ *  (at your option) any later version.
+ *
+ *  GRUB is distributed in the hope that it will be useful,
+ *  but WITHOUT ANY WARRANTY; without even the implied warranty of
+ *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ *  GNU General Public License for more details.
+ *
+ *  You should have received a copy of the GNU General Public License
+ *  along with GRUB.  If not, see <http://www.gnu.org/licenses/>.
+ */
+
+#include <grub/types.h>
+#include <grub/misc.h>
+#include <grub/decompressor.h>
+
+void *
+memset (void *s, int c, grub_size_t len)
+{
+  grub_uint8_t *ptr;
+  for (ptr = s; len; ptr++, len--)
+    *ptr = c;
+  return s;
+}
+
+void *
+grub_memmove (void *dest, const void *src, grub_size_t n)
+{
+  char *d = (char *) dest;
+  const char *s = (const char *) src;
+
+  if (d < s)
+    while (n--)
+      *d++ = *s++;
+  else
+    {
+      d += n;
+      s += n;
+
+      while (n--)
+	*--d = *--s;
+    }
+
+  return dest;
+}
+
+int
+grub_memcmp (const void *s1, const void *s2, grub_size_t n)
+{
+  const char *t1 = s1;
+  const char *t2 = s2;
+
+  while (n--)
+    {
+      if (*t1 != *t2)
+	return (int) *t1 - (int) *t2;
+
+      t1++;
+      t2++;
+    }
+
+  return 0;
+}
+
+int memcmp (const void *s1, const void *s2, grub_size_t n)
+  __attribute__ ((alias ("grub_memcmp")));
+
+void *memmove (void *dest, const void *src, grub_size_t n)
+  __attribute__ ((alias ("grub_memmove")));
+
+void *memcpy (void *dest, const void *src, grub_size_t n)
+  __attribute__ ((alias ("grub_memmove")));
+
+void *grub_decompressor_scratch;
+
+void
+find_scratch (void *src, void *dst, unsigned long srcsize,
+	      unsigned long dstsize)
+{
+#ifdef _mips
+  /* Decoding from ROM.  */
+  if (((grub_addr_t) src & 0x10000000))
+    {
+      grub_decompressor_scratch = (void *) ALIGN_UP((grub_addr_t) dst + dstsize,
+						    256);
+      return;
+    }
+#endif
+  if ((char *) src + srcsize > (char *) dst + dstsize)
+    grub_decompressor_scratch = (void *) ALIGN_UP ((grub_addr_t) src + srcsize,
+						   256);
+  else
+    grub_decompressor_scratch = (void *) ALIGN_UP ((grub_addr_t) dst + dstsize,
+						   256);
+  return;
+}
diff --git a/grub-core/boot/decompressor/none.c b/grub-core/boot/decompressor/none.c
new file mode 100644
index 0000000..44f56ce
--- /dev/null
+++ b/grub-core/boot/decompressor/none.c
@@ -0,0 +1,39 @@
+/*
+ *  GRUB  --  GRand Unified Bootloader
+ *  Copyright (C) 2010  Free Software Foundation, Inc.
+ *
+ *  GRUB is free software: you can redistribute it and/or modify
+ *  it under the terms of the GNU General Public License as published by
+ *  the Free Software Foundation, either version 3 of the License, or
+ *  (at your option) any later version.
+ *
+ *  GRUB is distributed in the hope that it will be useful,
+ *  but WITHOUT ANY WARRANTY; without even the implied warranty of
+ *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ *  GNU General Public License for more details.
+ *
+ *  You should have received a copy of the GNU General Public License
+ *  along with GRUB.  If not, see <http://www.gnu.org/licenses/>.
+ */
+
+#include <grub/decompressor.h>
+
+void
+grub_decompress_core (void *src, void *dest, unsigned long n,
+		      unsigned long dstsize __attribute__ ((unused)))
+{
+  char *d = (char *) dest;
+  const char *s = (const char *) src;
+
+  if (d < s)
+    while (n--)
+      *d++ = *s++;
+  else
+    {
+      d += n;
+      s += n;
+
+      while (n--)
+	*--d = *--s;
+    }
+}
diff --git a/grub-core/boot/decompressor/xz.c b/grub-core/boot/decompressor/xz.c
new file mode 100644
index 0000000..2279118
--- /dev/null
+++ b/grub-core/boot/decompressor/xz.c
@@ -0,0 +1,60 @@
+/*
+ *  GRUB  --  GRand Unified Bootloader
+ *  Copyright (C) 2010  Free Software Foundation, Inc.
+ *
+ *  GRUB is free software: you can redistribute it and/or modify
+ *  it under the terms of the GNU General Public License as published by
+ *  the Free Software Foundation, either version 3 of the License, or
+ *  (at your option) any later version.
+ *
+ *  GRUB is distributed in the hope that it will be useful,
+ *  but WITHOUT ANY WARRANTY; without even the implied warranty of
+ *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ *  GNU General Public License for more details.
+ *
+ *  You should have received a copy of the GNU General Public License
+ *  along with GRUB.  If not, see <http://www.gnu.org/licenses/>.
+ */
+
+#include <grub/types.h>
+#include <grub/misc.h>
+#include <grub/decompressor.h>
+
+#include "xz.h"
+#include "xz_stream.h"
+
+void
+grub_decompress_core (void *src, void *dst, unsigned long srcsize,
+		      unsigned long dstsize)
+{
+  struct xz_dec *dec;
+  struct xz_buf buf;
+
+  find_scratch (src, dst, srcsize, dstsize);
+
+  dec = xz_dec_init (GRUB_DECOMPRESSOR_DICT_SIZE);
+
+  buf.in = src;
+  buf.in_pos = 0;
+  buf.in_size = srcsize;
+  buf.out = dst;
+  buf.out_pos = 0;
+  buf.out_size = dstsize;
+
+  while (buf.in_pos != buf.in_size)
+    {
+      enum xz_ret xzret;
+      xzret = xz_dec_run (dec, &buf);
+      switch (xzret)
+	{
+	case XZ_MEMLIMIT_ERROR:
+	case XZ_FORMAT_ERROR:
+	case XZ_OPTIONS_ERROR:
+	case XZ_DATA_ERROR:
+	case XZ_BUF_ERROR:
+	  return;
+	default:
+	  break;
+	}
+    }
+}
diff --git a/grub-core/boot/i386/pc/boot.S b/grub-core/boot/i386/pc/boot.S
new file mode 100644
index 0000000..635599a
--- /dev/null
+++ b/grub-core/boot/i386/pc/boot.S
@@ -0,0 +1,481 @@
+/* -*-Asm-*- */
+/*
+ *  GRUB  --  GRand Unified Bootloader
+ *  Copyright (C) 1999,2000,2001,2002,2005,2006,2007,2008,2009  Free Software Foundation, Inc.
+ *
+ *  GRUB is free software: you can redistribute it and/or modify
+ *  it under the terms of the GNU General Public License as published by
+ *  the Free Software Foundation, either version 3 of the License, or
+ *  (at your option) any later version.
+ *
+ *  GRUB is distributed in the hope that it will be useful,
+ *  but WITHOUT ANY WARRANTY; without even the implied warranty of
+ *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ *  GNU General Public License for more details.
+ *
+ *  You should have received a copy of the GNU General Public License
+ *  along with GRUB.  If not, see <http://www.gnu.org/licenses/>.
+ */
+
+#include <grub/symbol.h>
+#include <grub/boot.h>
+#include <grub/machine/boot.h>
+
+/*
+ *  defines for the code go here
+ */
+
+	/* Print message string */
+#define MSG(x)	movw $x, %si; call LOCAL(message)
+#define ERR(x)	movw $x, %si; jmp LOCAL(error_message)
+
+	.file	"boot.S"
+
+	.text
+
+	/* Tell GAS to generate 16-bit instructions so that this code works
+	   in real mode. */
+	.code16
+
+.globl _start, start;
+_start:
+start:
+	/*
+	 * _start is loaded at 0x7c00 and is jumped to with CS:IP 0:0x7c00
+	 */
+
+	/*
+	 * Beginning of the sector is compatible with the FAT/HPFS BIOS
+	 * parameter block.
+	 */
+
+	jmp	LOCAL(after_BPB)
+	nop	/* do I care about this ??? */
+
+	/*
+	 * This space is for the BIOS parameter block!!!!  Don't change
+	 * the first jump, nor start the code anywhere but right after
+	 * this area.
+	 */
+
+	. = _start + GRUB_BOOT_MACHINE_BPB_START
+	. = _start + 4
+
+	/* scratch space */
+mode:
+	.byte	0
+disk_address_packet:
+sectors:
+	.long	0
+heads:
+	.long	0
+cylinders:
+	.word	0
+sector_start:
+	.byte	0
+head_start:
+	.byte	0
+cylinder_start:
+	.word	0
+	/* more space... */
+
+	. = _start + GRUB_BOOT_MACHINE_BPB_END
+
+	/*
+	 * End of BIOS parameter block.
+	 */
+
+kernel_address:
+	.word	GRUB_BOOT_MACHINE_KERNEL_ADDR
+
+	. = _start + GRUB_BOOT_MACHINE_KERNEL_SECTOR
+kernel_sector:
+	.long	1, 0
+
+	. = _start + GRUB_BOOT_MACHINE_BOOT_DRIVE
+boot_drive:
+	.byte 0xff	/* the disk to load kernel from */
+			/* 0xff means use the boot drive */
+
+LOCAL(after_BPB):
+
+/* general setup */
+	cli		/* we're not safe here! */
+
+        /*
+         * This is a workaround for buggy BIOSes which don't pass boot
+         * drive correctly. If GRUB is installed into a HDD, check if
+         * DL is masked correctly. If not, assume that the BIOS passed
+         * a bogus value and set DL to 0x80, since this is the only
+         * possible boot drive. If GRUB is installed into a floppy,
+         * this does nothing (only jump).
+         */
+	. = _start + GRUB_BOOT_MACHINE_DRIVE_CHECK
+boot_drive_check:
+        jmp     3f	/* grub-setup may overwrite this jump */
+        testb   $0x80, %dl
+        jz      2f
+3:
+	/* Ignore %dl different from 0-0x0f and 0x80-0x8f.  */
+	testb   $0x70, %dl
+	jz      1f
+2:	
+        movb    $0x80, %dl
+1:
+	/*
+	 * ljmp to the next instruction because some bogus BIOSes
+	 * jump to 07C0:0000 instead of 0000:7C00.
+	 */
+	ljmp	$0, $real_start
+
+real_start:
+
+	/* set up %ds and %ss as offset from 0 */
+	xorw	%ax, %ax
+	movw	%ax, %ds
+	movw	%ax, %ss
+
+	/* set up the REAL stack */
+	movw	$GRUB_BOOT_MACHINE_STACK_SEG, %sp
+
+	sti		/* we're safe again */
+
+	/*
+	 *  Check if we have a forced disk reference here
+	 */
+	movb   boot_drive, %al
+	cmpb	$0xff, %al
+	je	1f
+	movb	%al, %dl
+1:
+	/* save drive reference first thing! */
+	pushw	%dx
+
+	/* print a notification message on the screen */
+	MSG(notification_string)
+
+	/* set %si to the disk address packet */
+	movw	$disk_address_packet, %si
+
+	/* check if LBA is supported */
+	movb	$0x41, %ah
+	movw	$0x55aa, %bx
+	int	$0x13
+
+	/*
+	 *  %dl may have been clobbered by INT 13, AH=41H.
+	 *  This happens, for example, with AST BIOS 1.04.
+	 */
+	popw	%dx
+	pushw	%dx
+
+	/* use CHS if fails */
+	jc	LOCAL(chs_mode)
+	cmpw	$0xaa55, %bx
+	jne	LOCAL(chs_mode)
+
+	andw	$1, %cx
+	jz	LOCAL(chs_mode)
+
+lba_mode:
+	xorw	%ax, %ax
+	movw	%ax, 4(%si)
+
+	incw	%ax
+	/* set the mode to non-zero */
+	movb	%al, -1(%si)
+
+	/* the blocks */
+	movw	%ax, 2(%si)
+
+	/* the size and the reserved byte */
+	movw	$0x0010, (%si)
+
+	/* the absolute address */
+	movl	kernel_sector, %ebx
+	movl	%ebx, 8(%si)
+	movl	kernel_sector + 4, %ebx
+	movl	%ebx, 12(%si)
+
+	/* the segment of buffer address */
+	movw	$GRUB_BOOT_MACHINE_BUFFER_SEG, 6(%si)
+
+/*
+ * BIOS call "INT 0x13 Function 0x42" to read sectors from disk into memory
+ *	Call with	%ah = 0x42
+ *			%dl = drive number
+ *			%ds:%si = segment:offset of disk address packet
+ *	Return:
+ *			%al = 0x0 on success; err code on failure
+ */
+
+	movb	$0x42, %ah
+	int	$0x13
+
+	/* LBA read is not supported, so fallback to CHS.  */
+	jc	LOCAL(chs_mode)
+
+	movw	$GRUB_BOOT_MACHINE_BUFFER_SEG, %bx
+	jmp	LOCAL(copy_buffer)
+
+LOCAL(chs_mode):
+	/*
+	 *  Determine the hard disk geometry from the BIOS!
+	 *  We do this first, so that LS-120 IDE floppies work correctly.
+	 */
+	movb	$8, %ah
+	int	$0x13
+	jnc	LOCAL(final_init)
+
+	/*
+	 *  The call failed, so maybe use the floppy probe instead.
+	 */
+	testb	$GRUB_BOOT_MACHINE_BIOS_HD_FLAG, %dl
+	jz	LOCAL(floppy_probe)
+
+	/* Nope, we definitely have a hard disk, and we're screwed. */
+	ERR(hd_probe_error_string)
+
+LOCAL(final_init):
+	/* set the mode to zero */
+	movzbl	%dh, %eax
+	movb	%ah, -1(%si)
+
+	/* save number of heads */
+	incw	%ax
+	movl	%eax, 4(%si)
+
+	movzbw	%cl, %dx
+	shlw	$2, %dx
+	movb	%ch, %al
+	movb	%dh, %ah
+
+	/* save number of cylinders */
+	incw	%ax
+	movw	%ax, 8(%si)
+
+	movzbw	%dl, %ax
+	shrb	$2, %al
+
+	/* save number of sectors */
+	movl	%eax, (%si)
+
+setup_sectors:
+	/* load logical sector start (top half) */
+	movl	kernel_sector + 4, %eax
+
+	orl	%eax, %eax
+	jnz	LOCAL(geometry_error)
+
+	/* load logical sector start (bottom half) */
+	movl	kernel_sector, %eax
+
+	/* zero %edx */
+	xorl	%edx, %edx
+
+	/* divide by number of sectors */
+	divl	(%si)
+
+	/* save sector start */
+	movb	%dl, %cl
+
+	xorw	%dx, %dx	/* zero %edx */
+	divl	4(%si)		/* divide by number of heads */
+
+	/* do we need too many cylinders? */
+	cmpw	8(%si), %ax
+	jge	LOCAL(geometry_error)
+
+	/* normalize sector start (1-based) */
+	incb	%cl
+
+	/* low bits of cylinder start */
+	movb	%al, %ch
+
+	/* high bits of cylinder start */
+	xorb	%al, %al
+	shrw	$2, %ax
+	orb	%al, %cl
+
+	/* save head start */
+	movb	%dl, %al
+
+	/* restore %dl */
+	popw	%dx
+
+	/* head start */
+	movb	%al, %dh
+
+/*
+ * BIOS call "INT 0x13 Function 0x2" to read sectors from disk into memory
+ *	Call with	%ah = 0x2
+ *			%al = number of sectors
+ *			%ch = cylinder
+ *			%cl = sector (bits 6-7 are high bits of "cylinder")
+ *			%dh = head
+ *			%dl = drive (0x80 for hard disk, 0x0 for floppy disk)
+ *			%es:%bx = segment:offset of buffer
+ *	Return:
+ *			%al = 0x0 on success; err code on failure
+ */
+
+	movw	$GRUB_BOOT_MACHINE_BUFFER_SEG, %bx
+	movw	%bx, %es	/* load %es segment with disk buffer */
+
+	xorw	%bx, %bx	/* %bx = 0, put it at 0 in the segment */
+	movw	$0x0201, %ax	/* function 2 */
+	int	$0x13
+
+	jc	LOCAL(read_error)
+
+	movw	%es, %bx
+
+LOCAL(copy_buffer):
+	/*
+	 * We need to save %cx and %si because the startup code in
+	 * kernel uses them without initializing them.
+	 */
+	pusha
+	pushw	%ds
+
+	movw	$0x100, %cx
+	movw	%bx, %ds
+	xorw	%si, %si
+	movw	$GRUB_BOOT_MACHINE_KERNEL_ADDR, %di
+	movw	%si, %es
+
+	cld
+
+	rep
+	movsw
+
+	popw	%ds
+	popa
+
+	/* boot kernel */
+	jmp	*(kernel_address)
+
+/* END OF MAIN LOOP */
+
+/*
+ * BIOS Geometry translation error (past the end of the disk geometry!).
+ */
+LOCAL(geometry_error):
+	ERR(geometry_error_string)
+
+/*
+ * Read error on the disk.
+ */
+LOCAL(read_error):
+	movw	$read_error_string, %si
+LOCAL(error_message):
+	call	LOCAL(message)
+LOCAL(general_error):
+	MSG(general_error_string)
+
+/* go here when you need to stop the machine hard after an error condition */
+        /* tell the BIOS a boot failure, which may result in no effect */
+        int	$0x18
+LOCAL(stop):
+	jmp	LOCAL(stop)
+
+notification_string:	.asciz "GRUB "
+geometry_error_string:	.asciz "Geom"
+hd_probe_error_string:	.asciz "Hard Disk"
+read_error_string:	.asciz "Read"
+general_error_string:	.asciz " Error\r\n"
+
+/*
+ * message: write the string pointed to by %si
+ *
+ *   WARNING: trashes %si, %ax, and %bx
+ */
+
+	/*
+	 * Use BIOS "int 10H Function 0Eh" to write character in teletype mode
+	 *	%ah = 0xe	%al = character
+	 *	%bh = page	%bl = foreground color (graphics modes)
+	 */
+1:
+	movw	$0x0001, %bx
+	movb	$0xe, %ah
+	int	$0x10		/* display a byte */
+LOCAL(message):
+	lodsb
+	cmpb	$0, %al
+	jne	1b	/* if not end of string, jmp to display */
+	ret
+
+	/*
+	 *  Windows NT breaks compatibility by embedding a magic
+	 *  number here.
+	 */
+
+	. = _start + GRUB_BOOT_MACHINE_WINDOWS_NT_MAGIC
+nt_magic:
+	.long 0
+	.word 0
+
+	/*
+	 *  This is where an MBR would go if on a hard disk.  The code
+	 *  here isn't even referenced unless we're on a floppy.  Kinda
+	 *  sneaky, huh?
+	 */
+
+	. = _start + GRUB_BOOT_MACHINE_PART_START
+part_start:
+
+probe_values:
+	.byte	36, 18, 15, 9, 0
+
+LOCAL(floppy_probe):
+/*
+ *  Perform floppy probe.
+ */
+
+	movw	$probe_values - 1, %si
+
+LOCAL(probe_loop):
+	/* reset floppy controller INT 13h AH=0 */
+	xorw	%ax, %ax
+	int	$0x13
+
+	incw	%si
+	movb	(%si), %cl
+
+	/* if number of sectors is 0, display error and die */
+	cmpb	$0, %cl
+	jne	1f
+
+/*
+ * Floppy disk probe failure.
+ */
+	MSG(fd_probe_error_string)
+	jmp	LOCAL(general_error)
+
+/* "Floppy" */
+fd_probe_error_string:	.asciz "Floppy"
+
+1:
+	/* perform read */
+	movw	$GRUB_BOOT_MACHINE_BUFFER_SEG, %bx
+	movw	%bx, %es
+	xorw	%bx, %bx
+	movw	$0x201, %ax
+	movb	$0, %ch
+	movb	$0, %dh
+	int	$0x13
+
+	/* if error, jump to "LOCAL(probe_loop)" */
+	jc	LOCAL(probe_loop)
+
+	/* %cl is already the correct value! */
+	movb	$1, %dh
+	movb	$79, %ch
+
+	jmp	LOCAL(final_init)
+
+	. = _start + GRUB_BOOT_MACHINE_PART_END
+
+/* the last 2 bytes in the sector 0 contain the signature */
+	.word	GRUB_BOOT_MACHINE_SIGNATURE
diff --git a/grub-core/boot/i386/pc/cdboot.S b/grub-core/boot/i386/pc/cdboot.S
new file mode 100644
index 0000000..33569ce
--- /dev/null
+++ b/grub-core/boot/i386/pc/cdboot.S
@@ -0,0 +1,173 @@
+/* -*-Asm-*- */
+/*
+ *  GRUB  --  GRand Unified Bootloader
+ *  Copyright (C) 2008,2009  Free Software Foundation, Inc.
+ *
+ *  GRUB is free software: you can redistribute it and/or modify
+ *  it under the terms of the GNU General Public License as published by
+ *  the Free Software Foundation, either version 3 of the License, or
+ *  (at your option) any later version.
+ *
+ *  GRUB is distributed in the hope that it will be useful,
+ *  but WITHOUT ANY WARRANTY; without even the implied warranty of
+ *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ *  GNU General Public License for more details.
+ *
+ *  You should have received a copy of the GNU General Public License
+ *  along with GRUB.  If not, see <http://www.gnu.org/licenses/>.
+ */
+
+#include <grub/symbol.h>
+#include <grub/boot.h>
+#include <grub/machine/boot.h>
+#include <grub/machine/kernel.h>
+#include <multiboot.h>
+
+        .file   "cdboot.S"
+
+#define CODE_ADDR	0x6000
+#define DATA_ADDR	((GRUB_BOOT_MACHINE_KERNEL_ADDR) + 0x200)
+
+#define CDSEC_SHIFT	11
+#define CDBLK_LENG	16
+
+	.text
+
+        .code16
+
+        .globl  start, _start
+
+start:
+_start:
+	call	LOCAL(next)
+
+LOCAL(next):
+	jmp	1f
+
+	. = start + 8
+
+bi_pvd:
+	.long 0		/* LBA of primary volume descriptor.  */
+bi_file:
+	.long 0		/* LBA of boot file. */
+bi_length:
+	.long 0		/* Length of boot file. */
+bi_csum:
+	.long 0		/* Checksum of boot file */
+bi_reserved:
+	.space (10*4)	/* Reserved */
+
+1:
+	popw	%bx
+
+	/* Boot from CDROM.  */
+
+	xorw	%ax, %ax
+	movw	%ax, %ss
+	movw	$(CODE_ADDR), %sp
+	movw	%ax, %ds
+	movw	%ax, %es
+
+	movw	$(0x7C00 + err_noboot_msg - start), %si
+	movl	%cs: bi_length - LOCAL(next)(%bx), %ecx
+	orl	%ecx, %ecx
+	jz	LOCAL(fail)
+
+	addl	$((1 << CDSEC_SHIFT) - 1), %ecx
+	shrl	$CDSEC_SHIFT, %ecx
+
+	movl	%cs: bi_file - LOCAL(next)(%bx), %esi
+
+	call	LOCAL(read_cdrom)
+
+	ljmp	$(DATA_ADDR >> 4), $0
+
+/*
+ * Parameters:
+ *   esi: start sector
+ *   ecx: number of sectors
+ */
+LOCAL(read_cdrom):
+	xorl	%eax, %eax
+
+	/* Number of blocks to read.  */
+	pushw	$CDBLK_LENG
+
+	/* Block number.  */
+	pushl	%eax
+	pushl	%esi
+
+	/* Buffer address.  */
+	pushw	$((DATA_ADDR - 0x400)>> 4)
+	pushl	%eax
+	pushw	$0x10
+
+	xorl	%edi, %edi
+	movw	%sp, %si
+
+1:
+	movw	0x10(%si), %di
+	cmpl	%ecx, %edi
+	jbe	2f
+	movl	%ecx, %edi
+
+2:
+	mov	%di, 2(%si)
+
+	pushl	%ecx
+
+	movb	$0x42, %ah
+	int	$0x13
+
+	jnc	3f
+
+	movb	$0x42, %ah		/* Try again.  */
+	int	$0x13
+
+	jnc	3f
+
+2:
+	shrw	$1, %di			/* Reduce transfer size.  */
+	jz	LOCAL(cdrom_fail)
+	movw	%di, 0x10(%si)
+	movw	%di, 2(%si)
+	movb	$0x42, %ah
+	int	$0x13
+	jc	2b
+
+3:
+
+	movw	%di, %ax
+	shlw	$(CDSEC_SHIFT - 4), %ax
+	addw	%ax, 6(%si)
+	addl	%edi, 8(%si)
+
+	popl	%ecx
+	subl	%edi, %ecx
+	jnz	1b
+
+	addw	$0x12, %sp
+	ret
+
+LOCAL(cdrom_fail):
+	movw	$(0x7C00 + err_cdfail_msg - start), %si
+
+LOCAL(fail):
+	movb	$0x0e, %ah
+	xorw	%bx, %bx
+1:
+	lodsb	(%si), %al
+	int	$0x10
+	cmpb	$0, %al
+	jne	1b
+1:	jmp	1b
+
+err_noboot_msg:
+	.ascii	"no boot info\0"
+
+err_cdfail_msg:
+	.ascii	"cdrom read fails\0"
+
+	. = start + 0x1FF
+
+	.byte	0
diff --git a/grub-core/boot/i386/pc/diskboot.S b/grub-core/boot/i386/pc/diskboot.S
new file mode 100644
index 0000000..92f223f
--- /dev/null
+++ b/grub-core/boot/i386/pc/diskboot.S
@@ -0,0 +1,380 @@
+/*
+ *  GRUB  --  GRand Unified Bootloader
+ *  Copyright (C) 1999,2000,2001,2002,2006,2007,2009,2010   Free Software Foundation, Inc.
+ *
+ *  GRUB is free software: you can redistribute it and/or modify
+ *  it under the terms of the GNU General Public License as published by
+ *  the Free Software Foundation, either version 3 of the License, or
+ *  (at your option) any later version.
+ *
+ *  GRUB is distributed in the hope that it will be useful,
+ *  but WITHOUT ANY WARRANTY; without even the implied warranty of
+ *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ *  GNU General Public License for more details.
+ *
+ *  You should have received a copy of the GNU General Public License
+ *  along with GRUB.  If not, see <http://www.gnu.org/licenses/>.
+ */
+
+#include <grub/symbol.h>
+#include <grub/machine/boot.h>
+
+/*
+ *  defines for the code go here
+ */
+
+#define MSG(x)	movw $x, %si; call LOCAL(message)
+
+	.file	"diskboot.S"
+
+	.text
+
+	/* Tell GAS to generate 16-bit instructions so that this code works
+	   in real mode. */
+	.code16
+
+	.globl	start, _start
+start:
+_start:
+	/*
+	 * _start is loaded at 0x2000 and is jumped to with
+	 * CS:IP 0:0x2000 in kernel.
+	 */
+
+	/*
+	 * we continue to use the stack for boot.img and assume that
+	 * some registers are set to correct values. See boot.S
+	 * for more information.
+	 */
+
+	/* save drive reference first thing! */
+	pushw	%dx
+
+	/* print a notification message on the screen */
+	pushw	%si
+	MSG(notification_string)
+	popw	%si
+
+	/* this sets up for the first run through "bootloop" */
+	movw	$(firstlist - GRUB_BOOT_MACHINE_LIST_SIZE), %di
+
+	/* save the sector number of the second sector in %ebp */
+	movl	(%di), %ebp
+
+        /* this is the loop for reading the rest of the kernel in */
+LOCAL(bootloop):
+
+	/* check the number of sectors to read */
+	cmpw	$0, 8(%di)
+
+	/* if zero, go to the start function */
+	je	LOCAL(bootit)
+
+LOCAL(setup_sectors):
+	/* check if we use LBA or CHS */
+	cmpb	$0, -1(%si)
+
+	/* use CHS if zero, LBA otherwise */
+	je	LOCAL(chs_mode)
+
+	/* load logical sector start */
+	movl	(%di), %ebx
+	movl	4(%di), %ecx
+
+	/* the maximum is limited to 0x7f because of Phoenix EDD */
+	xorl	%eax, %eax
+	movb	$0x7f, %al
+
+	/* how many do we really want to read? */
+	cmpw	%ax, 8(%di)	/* compare against total number of sectors */
+
+	/* which is greater? */
+	jg	1f
+
+	/* if less than, set to total */
+	movw	8(%di), %ax
+
+1:
+	/* subtract from total */
+	subw	%ax, 8(%di)
+
+	/* add into logical sector start */
+	addl	%eax, (%di)
+	adcl	$0, 4(%di)
+
+	/* set up disk address packet */
+
+	/* the size and the reserved byte */
+	movw	$0x0010, (%si)
+
+	/* the number of sectors */
+	movw	%ax, 2(%si)
+
+	/* the absolute address */
+	movl	%ebx, 8(%si)
+	movl	%ecx, 12(%si)
+
+	/* the segment of buffer address */
+	movw	$GRUB_BOOT_MACHINE_BUFFER_SEG, 6(%si)
+
+	/* save %ax from destruction! */
+	pushw	%ax
+
+	/* the offset of buffer address */
+	movw	$0, 4(%si)
+
+/*
+ * BIOS call "INT 0x13 Function 0x42" to read sectors from disk into memory
+ *	Call with	%ah = 0x42
+ *			%dl = drive number
+ *			%ds:%si = segment:offset of disk address packet
+ *	Return:
+ *			%al = 0x0 on success; err code on failure
+ */
+
+	movb	$0x42, %ah
+	int	$0x13
+
+	jc	LOCAL(read_error)
+
+	movw	$GRUB_BOOT_MACHINE_BUFFER_SEG, %bx
+	jmp	LOCAL(copy_buffer)
+
+LOCAL(chs_mode):
+	/* load logical sector start (top half) */
+	movl	4(%di), %eax
+	orl	%eax, %eax
+	jnz	LOCAL(geometry_error)
+
+	/* load logical sector start (bottom half) */
+	movl	(%di), %eax
+
+	/* zero %edx */
+	xorl	%edx, %edx
+
+	/* divide by number of sectors */
+	divl	(%si)
+
+	/* save sector start */
+	movb	%dl, 10(%si)
+
+	xorl	%edx, %edx	/* zero %edx */
+	divl	4(%si)		/* divide by number of heads */
+
+	/* save head start */
+	movb	%dl, 11(%si)
+
+	/* save cylinder start */
+	movw	%ax, 12(%si)
+
+	/* do we need too many cylinders? */
+	cmpw	8(%si), %ax
+	jge	LOCAL(geometry_error)
+
+	/* determine the maximum sector length of this read */
+	movw	(%si), %ax	/* get number of sectors per track/head */
+
+	/* subtract sector start */
+	subb	10(%si), %al
+
+	/* how many do we really want to read? */
+	cmpw	%ax, 8(%di)	/* compare against total number of sectors */
+
+
+	/* which is greater? */
+	jg	2f
+
+	/* if less than, set to total */
+	movw	8(%di), %ax
+
+2:
+	/* subtract from total */
+	subw	%ax, 8(%di)
+
+	/* add into logical sector start */
+	addl	%eax, (%di)
+	adcl	$0, 4(%di)
+
+/*
+ *  This is the loop for taking care of BIOS geometry translation (ugh!)
+ */
+
+	/* get high bits of cylinder */
+	movb	13(%si), %dl
+
+	shlb	$6, %dl		/* shift left by 6 bits */
+	movb	10(%si), %cl	/* get sector */
+
+	incb	%cl		/* normalize sector (sectors go
+					from 1-N, not 0-(N-1) ) */
+	orb	%dl, %cl	/* composite together */
+	movb	12(%si), %ch	/* sector+hcyl in cl, cylinder in ch */
+
+	/* restore %dx */
+	popw	%dx
+	pushw	%dx
+
+	/* head number */
+	movb	11(%si), %dh
+
+	pushw	%ax	/* save %ax from destruction! */
+
+/*
+ * BIOS call "INT 0x13 Function 0x2" to read sectors from disk into memory
+ *	Call with	%ah = 0x2
+ *			%al = number of sectors
+ *			%ch = cylinder
+ *			%cl = sector (bits 6-7 are high bits of "cylinder")
+ *			%dh = head
+ *			%dl = drive (0x80 for hard disk, 0x0 for floppy disk)
+ *			%es:%bx = segment:offset of buffer
+ *	Return:
+ *			%al = 0x0 on success; err code on failure
+ */
+
+	movw	$GRUB_BOOT_MACHINE_BUFFER_SEG, %bx
+	movw	%bx, %es	/* load %es segment with disk buffer */
+
+	xorw	%bx, %bx	/* %bx = 0, put it at 0 in the segment */
+	movb	$0x2, %ah	/* function 2 */
+	int	$0x13
+
+	jc	LOCAL(read_error)
+
+	/* save source segment */
+	movw	%es, %bx
+
+LOCAL(copy_buffer):
+
+	/* load addresses for copy from disk buffer to destination */
+	movw	10(%di), %es	/* load destination segment */
+
+	/* restore %ax */
+	popw	%ax
+
+	/* determine the next possible destination address (presuming
+		512 byte sectors!) */
+	shlw	$5, %ax		/* shift %ax five bits to the left */
+	addw	%ax, 10(%di)	/* add the corrected value to the destination
+				   address for next time */
+
+	/* save addressing regs */
+	pusha
+	pushw	%ds
+
+	/* get the copy length */
+	shlw	$3, %ax
+	movw	%ax, %cx
+
+	xorw	%di, %di	/* zero offset of destination addresses */
+	xorw	%si, %si	/* zero offset of source addresses */
+	movw	%bx, %ds	/* restore the source segment */
+
+	cld		/* sets the copy direction to forward */
+
+	/* perform copy */
+	rep		/* sets a repeat */
+	movsw		/* this runs the actual copy */
+
+	/* restore addressing regs and print a dot with correct DS
+	   (MSG modifies SI, which is saved, and unused AX and BX) */
+	popw	%ds
+	MSG(notification_step)
+	popa
+
+	/* check if finished with this dataset */
+	cmpw	$0, 8(%di)
+	jne	LOCAL(setup_sectors)
+
+	/* update position to load from */
+	subw	$GRUB_BOOT_MACHINE_LIST_SIZE, %di
+
+	/* jump to bootloop */
+	jmp	LOCAL(bootloop)
+
+/* END OF MAIN LOOP */
+
+LOCAL(bootit):
+	/* print a newline */
+	MSG(notification_done)
+	popw	%dx	/* this makes sure %dl is our "boot" drive */
+	ljmp	$0, $(GRUB_BOOT_MACHINE_KERNEL_ADDR + 0x200)
+
+
+/*
+ * BIOS Geometry translation error (past the end of the disk geometry!).
+ */
+LOCAL(geometry_error):
+	MSG(geometry_error_string)
+	jmp	LOCAL(general_error)
+
+/*
+ * Read error on the disk.
+ */
+LOCAL(read_error):
+	MSG(read_error_string)
+
+LOCAL(general_error):
+	MSG(general_error_string)
+
+/* go here when you need to stop the machine hard after an error condition */
+LOCAL(stop):	jmp	LOCAL(stop)
+
+notification_string:	.asciz "loading"
+
+notification_step:	.asciz "."
+notification_done:	.asciz "\r\n"
+
+geometry_error_string:	.asciz "Geom"
+read_error_string:	.asciz "Read"
+general_error_string:	.asciz " Error"
+
+/*
+ * message: write the string pointed to by %si
+ *
+ *   WARNING: trashes %si, %ax, and %bx
+ */
+
+	/*
+	 * Use BIOS "int 10H Function 0Eh" to write character in teletype mode
+	 *	%ah = 0xe	%al = character
+	 *	%bh = page	%bl = foreground color (graphics modes)
+	 */
+1:
+	movw	$0x0001, %bx
+	movb	$0xe, %ah
+	int	$0x10		/* display a byte */
+
+	incw	%si
+LOCAL(message):
+	movb	(%si), %al
+	cmpb	$0, %al
+	jne	1b	/* if not end of string, jmp to display */
+	ret
+
+/*
+ *  This area is an empty space between the main body of code below which
+ *  grows up (fixed after compilation, but between releases it may change
+ *  in size easily), and the lists of sectors to read, which grows down
+ *  from a fixed top location.
+ */
+
+	.word 0
+	.word 0
+
+	. = _start + 0x200 - GRUB_BOOT_MACHINE_LIST_SIZE
+
+        /* fill the first data listing with the default */
+blocklist_default_start:
+	/* this is the sector start parameter, in logical sectors from
+	   the start of the disk, sector 0 */
+	.long 2, 0
+blocklist_default_len:
+	/* this is the number of sectors to read.  grub-mkimage
+	   will fill this up */
+	.word 0
+blocklist_default_seg:
+	/* this is the segment of the starting address to load the data into */
+	.word (GRUB_BOOT_MACHINE_KERNEL_SEG + 0x20)
+
+firstlist:	/* this label has to be after the list data!!! */
diff --git a/grub-core/boot/i386/pc/lnxboot.S b/grub-core/boot/i386/pc/lnxboot.S
new file mode 100644
index 0000000..2c75960
--- /dev/null
+++ b/grub-core/boot/i386/pc/lnxboot.S
@@ -0,0 +1,299 @@
+/* -*-Asm-*- */
+/*
+ *  GRUB  --  GRand Unified Bootloader
+ *  Copyright (C) 2007,2008,2009  Free Software Foundation, Inc.
+ *
+ *  GRUB is free software: you can redistribute it and/or modify
+ *  it under the terms of the GNU General Public License as published by
+ *  the Free Software Foundation, either version 3 of the License, or
+ *  (at your option) any later version.
+ *
+ *  GRUB is distributed in the hope that it will be useful,
+ *  but WITHOUT ANY WARRANTY; without even the implied warranty of
+ *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ *  GNU General Public License for more details.
+ *
+ *  You should have received a copy of the GNU General Public License
+ *  along with GRUB.  If not, see <http://www.gnu.org/licenses/>.
+ */
+
+#include <config.h>
+#include <grub/symbol.h>
+#include <grub/boot.h>
+#include <grub/machine/boot.h>
+#include <grub/machine/kernel.h>
+#include <multiboot.h>
+
+        .file   "lnxboot.S"
+
+#define CODE_ADDR	0x6000
+#define CODE_SECTORS	1
+#define DATA_ADDR	((GRUB_BOOT_MACHINE_KERNEL_ADDR) + 0x200)
+
+#define BLCK_LENG	0x4000
+
+	.text
+
+        .code16
+
+        .globl  start, _start
+
+data_start:
+	xorl	%ebp, %ebp
+	jmp	LOCAL(linux_next)
+
+	. = data_start + 0x1F1
+
+setup_sects:
+	.byte	CODE_SECTORS
+root_flags:
+	.word	0
+syssize:
+	.word	0
+swap_dev:
+	.word	0
+ram_size:
+	.word	0
+vid_mode:
+	.word	0
+root_dev:
+	.word	0
+boot_flag:
+	.word	0xAA55
+
+start:
+_start:
+
+	jmp LOCAL(linux_init)
+
+	.ascii	"HdrS"			/* Header signature.  */
+	.word	0x0203			/* Header version number.  */
+
+realmode_swtch:
+	.word	0, 0			/* default_switch, SETUPSEG.  */
+start_sys_seg:
+	.word	0x1000			/* Obsolete.  */
+version_ptr:
+	.word	0			/* Version string ptr.  */
+type_of_loader:
+	.byte	0			/* Filled in by boot loader.  */
+loadflags:
+	.byte	1			/* Please load high.  */
+setup_move_size:
+	.word	0			/* Unused.  */
+code32_start:
+	.long	0x100000		/* 32-bit start address.  */
+ramdisk_image:
+	.long	0			/* Loaded ramdisk image address.  */
+ramdisk_size:
+	.long	0			/* Size of loaded ramdisk.  */
+bootsect_kludge:
+	.word	0, 0
+heap_end_ptr:
+	.word	0
+pad1:
+	.word	0
+cmd_line_ptr:
+	.long	0			/* Command line.  */
+ramdisk_max:
+	.long	0xffffffff		/* Highest allowed ramdisk address.  */
+
+gdt:
+	.long	0, 0, 0, 0		/* Must be zero.  */
+	.word	0xffff			/* 64 K segment size.  */
+gdt_src1:
+	.byte	0, 0 ,0			/* Low 24 bits of source address.  */
+	.byte	0x93			/* Access rights.  */
+	.byte	0			/* Extended access rights.  */
+gdt_src2:
+	.byte	0			/* High 8 bits of source address.  */
+	.word	0xffff			/* 64 K segment size.  */
+gdt_dst1:
+	.byte	0, 0, 0			/* Low 24 bits of target address.  */
+	.byte	0x93			/* Access rights.  */
+	.byte	0			/* Extended access rights.  */
+gdt_dst2:
+	.byte	0			/* High 8 bits of source address.  */
+	.long	0, 0, 0, 0		/* More space for the BIOS.  */
+
+reg_edx:
+	.byte	0x80, 0, 0xFF, 0xFF
+
+data_leng:
+	.long	0
+
+LOCAL(linux_init):
+	movw	%cs:(reg_edx - start), %dx
+	movl	%cs:(code32_start - start), %ebp
+
+LOCAL(linux_next):
+
+	call	LOCAL(normalize)
+
+LOCAL(normalize):
+	popw	%bx
+	subw	$(LOCAL(normalize) - start), %bx
+	shrw	$4, %bx
+	movw	%cs, %ax
+	addw	%bx, %ax
+	pushw	%ax
+	pushw	$(real_code - start)
+	lret				/* Jump to real_code.  */
+
+real_code:
+	subw	$0x20, %ax
+	movw	%ax, %ds
+	movw	(setup_sects - data_start), %cx
+	shlw	$7, %cx
+
+	/* Setup stack.  */
+
+	xorw	%si, %si
+	movw	%si, %ss
+	movw	$(CODE_ADDR), %sp
+
+	/* Move itself to 0:CODE_ADDR.  */
+
+	cld
+	movw	%cs, %ax
+	movw	%ax, %ds
+	movw	$(CODE_ADDR >> 4), %ax
+	movw	%ax, %es
+	movw	%si, %di
+
+	rep
+	movsl
+	ljmp	$(CODE_ADDR >> 4), $(real_code_2  - start)
+
+real_code_2:
+
+	xchgl	%ebp, %esi
+	orl	%esi, %esi
+	jnz	1f
+	movw	%ds, %si
+	shll	$4, %esi
+	addl	%ebp, %esi
+1:
+
+	pushw	%es
+	popw	%ds
+
+#if GRUB_KERNEL_I386_PC_NO_REED_SOLOMON_PART + 4 < 0x200
+	movl	$0x200, %ecx
+	addl	%ecx, %esi
+#else
+	movl	$(GRUB_KERNEL_I386_PC_NO_REED_SOLOMON_PART + 4), %ecx
+	addl	$0x200, %esi
+#endif
+	movl	$DATA_ADDR, %edi
+
+	call	LOCAL(move_memory)
+
+	/* Check for multiboot signature.  */
+	cmpl	$MULTIBOOT_HEADER_MAGIC, %ss:(DATA_ADDR + GRUB_KERNEL_I386_PC_NO_REED_SOLOMON_PART)
+	jz	1f
+
+	movl	(ramdisk_image - start), %esi
+	movl	(ramdisk_size - start), %ecx
+	movl	$(DATA_ADDR - 0x200), %edi
+	jmp	2f
+
+1:
+
+	movl	%ss:(DATA_ADDR + GRUB_KERNEL_MACHINE_COMPRESSED_SIZE), %ecx
+#if GRUB_KERNEL_I386_PC_NO_REED_SOLOMON_PART + 4 < 0x200
+	addl	$(GRUB_KERNEL_MACHINE_RAW_SIZE - 0x200), %ecx
+#else
+	addl	$(GRUB_KERNEL_MACHINE_RAW_SIZE - (GRUB_KERNEL_I386_PC_NO_REED_SOLOMON_PART + 4)), %ecx
+#endif
+
+2:
+	call	LOCAL(move_memory)
+
+	movsbl	%dh, %eax
+	movl	%eax, %ss:(DATA_ADDR + GRUB_KERNEL_MACHINE_INSTALL_DOS_PART)
+	movsbl	(reg_edx + 2 - start), %eax
+	movl	%eax, %ss:(DATA_ADDR + GRUB_KERNEL_MACHINE_INSTALL_BSD_PART)
+
+	movb	$0xFF, %dh
+
+	ljmp	$(DATA_ADDR >> 4), $0
+
+/*
+ * Parameters:
+ *   esi: source address
+ *   edi: target address
+ *   ecx: number of bytes
+ */
+
+LOCAL(move_memory):
+	incl	%ecx
+	andb	$0xFE, %cl
+	pushw	%dx
+1:
+	pushl	%esi
+	pushl	%edi
+	pushl	%ecx
+	cmpl	$BLCK_LENG, %ecx
+	jbe	2f
+	movl	$BLCK_LENG, %ecx
+2:
+	pushl	%ecx
+
+	movl	%esi, %eax
+	movw	%si, (gdt_src1 - start)
+	shrl	$16, %eax
+	movb	%al, (gdt_src1 + 2 - start)
+	movb	%ah, (gdt_src2 - start)
+
+	movl	%edi, %eax
+	movw	%di, (gdt_dst1 - start)
+	shrl	$16, %eax
+	movb	%al, (gdt_dst1 + 2 - start)
+	movb	%ah, (gdt_dst2 - start)
+
+	movw	$(gdt - start), %si
+	movb	$0x87, %ah
+	shrw	$1, %cx
+
+	int	$0x15
+
+	popl	%eax
+	popl	%ecx
+	popl	%edi
+	popl	%esi
+
+	jnc	2f
+	movw	$(err_int15_msg - start), %si
+	jmp	LOCAL(fail)
+
+2:
+
+	addl	%eax, %esi
+	addl	%eax, %edi
+	subl	%eax, %ecx
+	jnz	1b
+
+
+	popw	%dx
+	ret
+
+/*
+ * Parameters:
+ *   si: message
+ */
+
+LOCAL(fail):
+	movb	$0x0e, %ah
+	xorw	%bx, %bx
+1:
+	lodsb	(%si), %al
+	int	$0x10
+	cmpb	$0, %al
+	jne	1b
+1:	jmp	1b
+
+err_int15_msg:
+	.ascii	"move memory fails\0"
+
+	. = _start + CODE_SECTORS * 512
diff --git a/grub-core/boot/i386/pc/pxeboot.S b/grub-core/boot/i386/pc/pxeboot.S
new file mode 100644
index 0000000..446bfc7
--- /dev/null
+++ b/grub-core/boot/i386/pc/pxeboot.S
@@ -0,0 +1,42 @@
+/*
+ *  GRUB  --  GRand Unified Bootloader
+ *  Copyright (C) 2000,2005,2007,2008,2009,2010   Free Software Foundation, Inc.
+ *
+ *  GRUB is free software: you can redistribute it and/or modify
+ *  it under the terms of the GNU General Public License as published by
+ *  the Free Software Foundation, either version 3 of the License, or
+ *  (at your option) any later version.
+ *
+ *  GRUB is distributed in the hope that it will be useful,
+ *  but WITHOUT ANY WARRANTY; without even the implied warranty of
+ *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ *  GNU General Public License for more details.
+ *
+ *  You should have received a copy of the GNU General Public License
+ *  along with GRUB.  If not, see <http://www.gnu.org/licenses/>.
+ */
+
+#include <grub/machine/boot.h>
+
+	.file	"pxeboot.S"
+	.text
+
+	/* Start with the prehistoric environment... */
+	.code16
+
+	/* Let's go */
+.globl start, _start;
+_start:
+start:
+
+	/* Use drive number 0x7F for PXE */
+        movb	$GRUB_BOOT_MACHINE_PXE_DL, %dl
+
+	/* Jump to the real world */
+	ljmp	$0, $0x8200
+
+	/* This region is a junk. Do you say that this is wasteful?
+	   But I like that the memory layout of the body is consistent
+	   among different kernels rather than scamping just for 1.5KB. */
+	. = _start + 0x8200 - 0x7C00 - 0x200 - 1
+	.byte	0
diff --git a/grub-core/boot/i386/qemu/boot.S b/grub-core/boot/i386/qemu/boot.S
new file mode 100644
index 0000000..97aeab9
--- /dev/null
+++ b/grub-core/boot/i386/qemu/boot.S
@@ -0,0 +1,68 @@
+/*
+ *  GRUB  --  GRand Unified Bootloader
+ *  Copyright (C) 1999,2000,2001,2002,2003,2005,2006,2007,2008,2009 Free Software Foundation, Inc.
+ *
+ *  GRUB is free software: you can redistribute it and/or modify
+ *  it under the terms of the GNU General Public License as published by
+ *  the Free Software Foundation, either version 3 of the License, or
+ *  (at your option) any later version.
+ *
+ *  GRUB is distributed in the hope that it will be useful,
+ *  but WITHOUT ANY WARRANTY; without even the implied warranty of
+ *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ *  GNU General Public License for more details.
+ *
+ *  You should have received a copy of the GNU General Public License
+ *  along with GRUB.  If not, see <http://www.gnu.org/licenses/>.
+ */
+
+#include <config.h>
+#include <grub/symbol.h>
+#include <grub/i386/pc/memory.h>
+#include <grub/machine/memory.h>
+#include <grub/machine/boot.h>
+#include <grub/machine/kernel.h>
+
+	.text
+	.code16
+	.globl _start
+_start:
+	/* Disable interrupts.  */
+	cli
+
+	jmp	1f
+
+	. = _start + GRUB_BOOT_I386_QEMU_CORE_ENTRY_ADDR
+VARIABLE(grub_core_entry_addr)
+	.long	0
+1:
+
+	/* Set up %ds, %ss, and %es.  */
+	xorw	%ax, %ax
+	movw	%ax, %ds
+	movw	%ax, %ss
+	movw	%ax, %es
+
+	/* Set up the real mode stack.  */
+	movl	$GRUB_MEMORY_MACHINE_REAL_STACK, %esp
+
+	/* Transition to protected mode.  We use pushl to force generation
+	   of a flat return address.  */
+	pushl	$1f
+	DATA32	jmp real_to_prot
+	.code32
+1:
+	movl	grub_core_entry_addr, %edx
+	jmp	*%edx
+
+#include "../../../kern/i386/realmode.S"
+
+	/* Intel, in its infinite wisdom, decided to put the i8086 entry point
+	   *right here* and this is why we need this kludge.  */
+
+	. = GRUB_BOOT_MACHINE_SIZE - 16
+
+       .code16
+       
+	jmp	_start
+	. = GRUB_BOOT_MACHINE_SIZE
diff --git a/grub-core/boot/mips/startup_raw.S b/grub-core/boot/mips/startup_raw.S
new file mode 100644
index 0000000..6ba04c1
--- /dev/null
+++ b/grub-core/boot/mips/startup_raw.S
@@ -0,0 +1,196 @@
+/* startup.S - Startup code for the MIPS.  */
+/*
+ *  GRUB  --  GRand Unified Bootloader
+ *  Copyright (C) 2009  Free Software Foundation, Inc.
+ *
+ *  GRUB is free software: you can redistribute it and/or modify
+ *  it under the terms of the GNU General Public License as published by
+ *  the Free Software Foundation, either version 3 of the License, or
+ *  (at your option) any later version.
+ *
+ *  GRUB is distributed in the hope that it will be useful,
+ *  but WITHOUT ANY WARRANTY; without even the implied warranty of
+ *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ *  GNU General Public License for more details.
+ *
+ *  You should have received a copy of the GNU General Public License
+ *  along with GRUB.  If not, see <http://www.gnu.org/licenses/>.
+ */
+
+#include <grub/symbol.h>
+#include <grub/offsets.h>
+#include <grub/machine/memory.h>
+#include <grub/offsets.h>
+
+#define BASE_ADDR 8
+
+.extern __bss_start
+.extern _end
+
+	.globl __start, _start, start
+	.set noreorder
+	.set nomacro
+__start:
+_start:
+start:		
+
+	bal codestart
+	 nop
+base:	
+	. = _start + GRUB_KERNEL_MACHINE_COMPRESSED_SIZE
+compressed_size:
+	.long 0
+	. = _start + GRUB_KERNEL_MACHINE_UNCOMPRESSED_SIZE
+uncompressed_size:
+	.long 0
+codestart:
+	/* Save our base.  */
+	move $s0, $ra
+
+	/* Parse arguments. Has to be done before relocation.
+	So need to do it in asm.  */
+#ifdef GRUB_MACHINE_MIPS_YEELOONG
+	move $s2, $zero
+	move $s3, $zero
+	move $s4, $zero
+	move $s5, $zero
+
+	/* $a2 has the environment.  */
+	addiu $t0, $a2, 1
+	beq $t0, $zero, argdone
+	 nop
+	move $t0, $a2	
+argcont:	
+	lw $t1, 0($t0)
+	beq $t1, $zero, argdone
+	 nop
+#define DO_PARSE(str, reg) \
+	addiu $t2, $s0, (str-base);\
+	bal parsestr;\
+	 nop	    ;\
+	beq $v0, $zero, 1f;\
+	 nop		  ;\
+	b 2f;\
+	 move reg, $v0;	 \
+1:	
+	DO_PARSE (busclockstr, $s2)
+	DO_PARSE (cpuclockstr, $s3)
+	DO_PARSE (memsizestr, $s4)
+	DO_PARSE (highmemsizestr, $s5)
+2:	
+	b argcont
+	 addiu $t0, $t0, 4	 
+parsestr:
+	move $v0, $zero
+	move $t3, $t1
+3:	
+	lb $t4, 0($t2)
+	lb $t5, 0($t3)
+	addiu $t2, $t2, 1
+	addiu $t3, $t3, 1
+	beq $t5, $zero, 1f
+	 nop
+	beq $t5, $t4, 3b
+	 nop
+	bne $t4, $zero, 1f
+	 nop
+
+	addiu $t3, $t3, 0xffff
+digcont:	
+	lb $t5, 0($t3)
+	/* Substract '0' from digit.  */
+	addiu $t5, $t5, 0xffd0
+	bltz $t5, 1f
+	 nop
+	addiu $t4, $t5, 0xfff7
+	bgtz $t4, 1f
+	 nop
+	/* Multiply $v0 by 10 with bitshifts. */
+	sll $v0, $v0, 1
+	sll $t4, $v0, 2
+	addu $v0, $v0, $t4
+	addu $v0, $v0, $t5
+	addiu $t3, $t3, 1
+	b digcont
+	 nop
+1:
+	jr $ra
+	 nop
+busclockstr:	.asciiz "busclock="
+cpuclockstr:	.asciiz "cpuclock="
+memsizestr:	.asciiz "memsize="
+highmemsizestr:	.asciiz "highmemsize="
+	.p2align 2
+argdone:
+#endif
+	/* Copy the decompressor. */
+	lui $t1, %hi(base)
+	addiu $t1, $t1, %lo(base)
+	lui $t3, %hi(__bss_start)
+	addiu $t3, $t3, %lo(__bss_start)
+	move $t2, $s0
+
+1:
+	beq $t1, $t3, 2f
+	 lb $t4, 0($t2)
+	sb $t4, 0($t1)
+	addiu $t1, $t1, 1
+	b 1b
+	 addiu $t2, $t2, 1
+2:
+	/* Clean out its BSS.  */
+	lui $t1, %hi(__bss_start)
+	addiu $t1, $t1, %lo(__bss_start)
+	lui $t2, %hi(_end)
+	addiu $t2, $t2, %lo(_end)
+1:
+	beq $t1, $t2, 2f
+	 nop
+	sb $zero, 0($t1)
+	b 1b
+	 addiu $t1, $t1, 1
+2:
+	lui $a0, %hi(base)
+	addiu $a0, $a0, %lo(base)
+	lui $a1, %hi(_end)
+	addiu $a1, %lo(_end)
+	subu $a1,$a1,$a0
+
+#include "../../kern/mips/cache_flush.S"
+
+	/* Decompress the payload. */
+	lui $a0, %hi(__bss_start)
+	addiu $a0, $a0, %lo(__bss_start)
+	lui $t0, %hi(base)
+	addiu $t0, $t0, %lo(base)
+	subu $a0, $a0, $t0
+	addu $a0, $a0, $s0
+
+	lui $a1, %hi(GRUB_MACHINE_LINK_ADDR)
+	addiu $a1, %lo(GRUB_MACHINE_LINK_ADDR)
+	lw $a2, (GRUB_KERNEL_MACHINE_COMPRESSED_SIZE - BASE_ADDR)($s0)
+	lw $a3, (GRUB_KERNEL_MACHINE_UNCOMPRESSED_SIZE - BASE_ADDR)($s0)
+	move $s1, $a1
+
+	/* $a0 contains source compressed address, $a1 is destination,
+	   $a2 is compressed size, $a3 is uncompressed size. 
+	*/
+	move $s6, $a3
+
+	lui $t0, %hi(EXT_C(grub_decompress_core))
+	addiu $t0, $t0, %lo(EXT_C(grub_decompress_core))
+
+	lui $sp, %hi(_start - 256)
+	jalr $t0
+	 addiu $sp, $sp, %lo(_start - 256)
+	
+	move $a0, $s1
+	move $a1, $s6
+
+#include "../../kern/mips/cache_flush.S"
+
+	lui $t1, %hi(GRUB_MACHINE_LINK_ADDR)
+	addiu $t1, %lo(GRUB_MACHINE_LINK_ADDR)
+
+	jr $t1
+	 nop
diff --git a/grub-core/boot/mips/yeeloong/fwstart.S b/grub-core/boot/mips/yeeloong/fwstart.S
new file mode 100644
index 0000000..2eec876
--- /dev/null
+++ b/grub-core/boot/mips/yeeloong/fwstart.S
@@ -0,0 +1,632 @@
+/*
+ *  GRUB  --  GRand Unified Bootloader
+ *  Copyright (C) 2000,2001,2002,2003,2004,2005,2007,2008,2009,2010  Free Software Foundation, Inc.
+ *
+ *  GRUB is free software: you can redistribute it and/or modify
+ *  it under the terms of the GNU General Public License as published by
+ *  the Free Software Foundation, either version 3 of the License, or
+ *  (at your option) any later version.
+ *
+ *  GRUB is distributed in the hope that it will be useful,
+ *  but WITHOUT ANY WARRANTY; without even the implied warranty of
+ *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ *  GNU General Public License for more details.
+ *
+ *  You should have received a copy of the GNU General Public License
+ *  along with GRUB.  If not, see <http://www.gnu.org/licenses/>.
+ */
+
+#include <grub/mips/yeeloong/serial.h>
+#include <grub/mips/yeeloong/pci.h>
+#include <grub/mips/loongson.h>
+#include <grub/pci.h>
+#include <grub/machine/serial.h>
+#include <grub/ns8250.h>
+#include <grub/cs5536.h>
+#include <grub/smbus.h>
+
+	.set noreorder
+	.set noat
+	.set nomacro
+	.set mips3
+
+	.global start,_start,__start
+start:
+_start:
+__start:	
+	bal serial_hw_init
+	 nop
+	/* Find CS5536 controller.  */
+	/* $t4 chooses device in priority encoding.  */
+	/* Resulting value is kept in GRUB_MACHINE_PCI_CONF_CTRL_REG.
+	   This way we don't need to sacrifice a register for it.  */
+	/* We have only one bus (0). Function is 0.  */
+	lui $t0, %hi(GRUB_MACHINE_PCI_CONF_CTRL_REG_ADDR)
+	lui $t1, %hi(GRUB_MACHINE_PCI_CONFSPACE)
+	lui $t3, %hi(GRUB_CS5536_PCIID)
+	addiu $t3, $t3, %lo(GRUB_CS5536_PCIID)
+	ori $t4, $zero, 1
+	lui $a0, %hi(no_cs5536)
+1:
+	andi $t4, $t4, ((1 << GRUB_PCI_NUM_DEVICES) - 1)
+	beql  $t4, $zero, fatal
+	 addiu $a0, $a0, %lo(no_cs5536)
+	sw   $t4, %lo(GRUB_MACHINE_PCI_CONF_CTRL_REG_ADDR) ($t0)
+	lw   $t2, (%lo(GRUB_MACHINE_PCI_CONFSPACE) + GRUB_PCI_REG_PCI_ID) ($t1)
+	bnel  $t2, $t3, 1b
+	 sll $t4, $t4, 1
+
+	bal message
+	 addiu $a0, $a0, %lo(cs5536_found)
+	bal printhex
+	 move $a0, $t4
+
+	/* Initialise SMBus controller.  */
+	/* Set GPIO LBAR.  */
+	lui $a0, %hi(GRUB_CS5536_MSR_GPIO_BAR)
+	addiu $a0, $a0, %lo(GRUB_CS5536_MSR_GPIO_BAR)
+	ori $a1, $zero, GRUB_CS5536_LBAR_GPIO
+	/* Set mask to 0xf and enabled bit to 1.  */
+	bal wrmsr
+	 ori $a2, $zero, ((GRUB_CS5536_LBAR_MASK_MASK \
+	                  | GRUB_CS5536_LBAR_ENABLE) >> 32)
+
+	/* Set SMBUS LBAR.  */
+	lui $a0, %hi(GRUB_CS5536_MSR_SMB_BAR)
+	addiu $a0, $a0, %lo(GRUB_CS5536_MSR_SMB_BAR)
+	ori $a1, $zero, GRUB_CS5536_LBAR_SMBUS
+	/* Set mask to 0xf and enabled bit to 1.  */
+	bal wrmsr
+	 ori $a2, $zero, ((GRUB_CS5536_LBAR_MASK_MASK \
+	                   | GRUB_CS5536_LBAR_ENABLE) >> 32)
+
+	lui $a0, %hi(smbus_enabled)
+	bal message
+	  addiu $a0, $a0, %lo(smbus_enabled)
+
+	/* Enable SMBus controller pins.  */
+	lui $t0, %hi(GRUB_MACHINE_PCI_IO_BASE + GRUB_CS5536_LBAR_GPIO)
+	ori $t1, $zero, GRUB_GPIO_SMBUS_PINS
+	sw  $t1, %lo(GRUB_MACHINE_PCI_IO_BASE + GRUB_CS5536_LBAR_GPIO + GRUB_GPIO_REG_OUT_EN) ($t0)
+	sw  $t1, %lo(GRUB_MACHINE_PCI_IO_BASE + GRUB_CS5536_LBAR_GPIO + GRUB_GPIO_REG_OUT_AUX1) ($t0)
+	sw  $t1, %lo(GRUB_MACHINE_PCI_IO_BASE + GRUB_CS5536_LBAR_GPIO + GRUB_GPIO_REG_IN_EN) ($t0)
+	sw  $t1, %lo(GRUB_MACHINE_PCI_IO_BASE + GRUB_CS5536_LBAR_GPIO + GRUB_GPIO_REG_IN_AUX1) ($t0)
+
+	lui $t0, %hi(GRUB_MACHINE_PCI_IO_BASE + GRUB_CS5536_LBAR_SMBUS)
+
+	/* Disable SMB.  */
+	sb $zero, %lo(GRUB_MACHINE_PCI_IO_BASE + GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_CTRL2) ($t0)
+
+	/* Disable interrupts.  */
+	sb $zero, %lo(GRUB_MACHINE_PCI_IO_BASE + GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_CTRL1) ($t0)
+
+	/* Set as master.  */
+	sb $zero, %lo(GRUB_MACHINE_PCI_IO_BASE + GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_ADDR) ($t0)
+
+	/* Launch SMBus controller at slowest speed possible.  */
+	ori $t1, $zero, 0xff
+	sb $t1, %lo(GRUB_MACHINE_PCI_IO_BASE + GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_CTRL3) ($t0)
+	sb $t1, %lo(GRUB_MACHINE_PCI_IO_BASE + GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_CTRL2) ($t0)
+
+	/* Yeeloong has only one memory slot.  */
+	/* Output first byte on serial for debugging.  */
+	ori $a1, $zero, GRUB_SMB_RAM_START_ADDR
+	bal read_spd
+	 move $a0, $zero
+	bal printhex
+	 move $a0, $v0
+
+	bal read_spd
+	 ori $a0, $zero, GRUB_SMBUS_SPD_MEMORY_TYPE_ADDR
+	ori $t0, $zero, GRUB_SMBUS_SPD_MEMORY_TYPE_DDR2
+	lui $a0, %hi(unimplemented_memory_type)
+	bne $t0, $v0, fatal
+	 addiu $a0, $a0, %lo(unimplemented_memory_type)
+
+	/* And here is our goal: DDR2 controller initialisation.  */
+        lui	$t0, %hi(GRUB_CPU_LOONGSON_CORECFG)
+        ld	$t1, %lo(GRUB_CPU_LOONGSON_CORECFG) ($t0)
+	/* Use addiu for sign-extension.  */
+	addiu	$t2, $zero, ~(GRUB_CPU_LOONGSON_CORECFG_DISABLE_DDR2_SPACE|GRUB_CPU_LOONGSON_CORECFG_BUFFER_CPU)
+	and	$t1, $t1, $t2
+	sd	$t1, %lo (GRUB_CPU_LOONGSON_CORECFG) ($t0)
+
+	b continue
+
+	. = start + GRUB_CPU_LOONGSON_FLASH_TLB_REFILL - GRUB_CPU_LOONGSON_FLASH_START
+tlb_refill:	
+	mfc0 $s1, GRUB_CPU_LOONGSON_COP0_EPC
+	mfc0 $s2, GRUB_CPU_LOONGSON_COP0_BADVADDR
+	move $s3, $ra
+	lui $a0, %hi(epc)
+	bal message
+	 addiu $a0, $a0, %lo(epc)
+
+	bal printhex
+	 move $a0, $s1
+
+	lui $a0, %hi(badvaddr)
+	bal message
+	 addiu $a0, $a0, %lo(badvaddr)
+
+	bal printhex
+	 move $a0, $s2
+
+	lui $a0, %hi(return_msg)
+	bal message
+	 addiu $a0, $a0, %lo(return_msg)
+
+	bal printhex
+	 move $a0, $s3
+	
+	lui $a0, %hi(newline)
+	bal message
+	 addiu $a0, $a0, %lo(newline)
+
+	lui $a0, %hi(unhandled_tlb_refill)
+	b fatal
+	 addiu $a0, $a0, %lo(unhandled_tlb_refill)
+
+	. = start + GRUB_CPU_LOONGSON_FLASH_CACHE_ERROR - GRUB_CPU_LOONGSON_FLASH_START
+cache_error:
+	lui $a0, %hi(unhandled_cache_error)
+	b fatal
+	 addiu $a0, $a0, %lo(unhandled_cache_error)
+
+	. = start + GRUB_CPU_LOONGSON_FLASH_OTHER_EXCEPTION - GRUB_CPU_LOONGSON_FLASH_START
+other_exception:
+	mfc0 $s0, GRUB_CPU_LOONGSON_COP0_CAUSE
+	mfc0 $s1, GRUB_CPU_LOONGSON_COP0_EPC
+	mfc0 $s2, GRUB_CPU_LOONGSON_COP0_BADVADDR
+	lui $a0, %hi(cause)
+	bal message
+	 addiu $a0, $a0, %lo(cause)
+
+	bal printhex
+	 move $a0, $s0
+
+	lui $a0, %hi(epc)
+	bal message
+	 addiu $a0, $a0, %lo(epc)
+
+	bal printhex
+	 move $a0, $s1
+
+	lui $a0, %hi(badvaddr)
+	bal message
+	 addiu $a0, $a0, %lo(badvaddr)
+
+	bal printhex
+	 move $a0, $s2
+	
+	lui $a0, %hi(newline)
+	bal message
+	 addiu $a0, $a0, %lo(newline)
+	
+	lui $a0, %hi(unhandled_exception)
+	b fatal
+	 addiu $a0, $a0, %lo(unhandled_exception)
+
+	/* Same as similarly named C function but in asm since
+	   we need it early.  */
+	/* In: none. Out: none. Clobbered: $t0, $t1, $a0.  */
+serial_hw_init:
+	lui $t0, %hi (GRUB_MACHINE_SERIAL_PORT)
+
+	/* Turn off the interrupt.  */
+	sb $zero, (%lo (GRUB_MACHINE_SERIAL_PORT) + UART_IER)($t0)
+
+	/* Set DLAB.  */
+	ori $t1, $zero, UART_DLAB
+	sb  $t1, (%lo (GRUB_MACHINE_SERIAL_PORT) + UART_LCR)($t0)
+
+	/* Set the baud rate 115200.  */
+	ori $t1, $zero, GRUB_MACHINE_SERIAL_DIVISOR_115200
+	sb $t1, (%lo (GRUB_MACHINE_SERIAL_PORT) + UART_DLL)($t0) 
+	sb $zero, (%lo (GRUB_MACHINE_SERIAL_PORT) + UART_DLH)($t0) 
+
+	/* Set the line status.  */
+	ori $t1, $zero, (UART_NO_PARITY | UART_8BITS_WORD | UART_1_STOP_BIT)
+        sb  $t1, (%lo (GRUB_MACHINE_SERIAL_PORT) + UART_LCR)($t0)
+
+	/* Enable the FIFO.  */
+	ori $t1, $zero, UART_ENABLE_FIFO_TRIGGER1
+	sb $t1, (%lo (GRUB_MACHINE_SERIAL_PORT) + UART_FCR)($t0)
+
+	/* Turn on DTR and RTS.  */
+	ori $t1, $zero, UART_ENABLE_DTRRTS
+	sb  $t1, (%lo (GRUB_MACHINE_SERIAL_PORT) + UART_MCR)($t0)
+
+	/* Let message return to original caller.  */
+	lui  $a0, %hi(notification_string)
+	addiu $a0, $a0, %lo(notification_string)
+
+	/* Print message on serial console.  */
+	/* In: $a0 = asciiz message. Out: none. Clobbered: $t0, $t1, $a0.  */
+message:
+	lui $t0, %hi (GRUB_MACHINE_SERIAL_PORT)
+1:
+	lb $t1, (%lo (GRUB_MACHINE_SERIAL_PORT) + UART_LSR)($t0)
+	andi $t1, $t1, UART_EMPTY_TRANSMITTER
+	beq $t1, $zero, 1b
+	 nop
+	lb  $t1, 0($a0)
+	sb  $t1, (%lo (GRUB_MACHINE_SERIAL_PORT) + UART_TX)($t0)
+	bne $t1, $zero, 1b
+	 addiu $a0, $a0, 1
+	jr  $ra
+	 nop
+	
+	/* Print 32-bit hexadecimal on serial.
+           In:	$a0. Out: None. Clobbered: $a0, $t0, $t1, $t2
+	*/
+printhex:
+	lui $t0, %hi  (GRUB_MACHINE_SERIAL_PORT)
+	ori $t2, $zero, 8
+1:
+	lb $t1, (%lo (GRUB_MACHINE_SERIAL_PORT) + UART_LSR)($t0)
+	andi $t1, $t1, UART_EMPTY_TRANSMITTER
+	beq $t1, $zero, 1b
+	 nop
+	srl  $t1, $a0, 28
+	addiu $t1, $t1, -10
+	blt  $t1, $zero, 2f
+	 sll  $a0, $a0, 4
+	addiu $t1, $t1, 'A'-10-'0' 
+2:	addiu $t1, $t1, '0'+10
+	sb  $t1, (%lo (GRUB_MACHINE_SERIAL_PORT) + UART_TX)($t0)
+	addiu $t2, $t2, -1
+	bne $t2, $zero, 1b
+	 nop
+	jr  $ra
+	 nop
+
+fatal:
+	bal message
+	 nop
+self:
+	b self
+	 nop
+	
+	/* Write CS5536 MSR.
+           In:   $a0 address, $a1 lower word, $a2 upper word.
+           Out:	 None
+           Clobbered:	 $t0
+	*/
+wrmsr:
+	lui $t0, %hi(GRUB_MACHINE_PCI_CONFSPACE)
+	sw  $a0, (%lo(GRUB_MACHINE_PCI_CONFSPACE) + GRUB_CS5536_MSR_MAILBOX_ADDR) ($t0)
+	sw  $a1, (%lo(GRUB_MACHINE_PCI_CONFSPACE) + GRUB_CS5536_MSR_MAILBOX_DATA0) ($t0)
+	jr $ra
+	 sw  $a2, (%lo(GRUB_MACHINE_PCI_CONFSPACE) + GRUB_CS5536_MSR_MAILBOX_DATA1) ($t0)
+
+	/* Wait for SMBus data or empty transmitter.  */
+	/* In: $a0 = exception handler. Out: none. Clobbered: $t0, $t1  */
+smbus_wait:
+1:	
+	lui $t0, %hi(GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_STATUS + GRUB_MACHINE_PCI_IO_BASE)
+	lb $t0, %lo(GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_STATUS + GRUB_MACHINE_PCI_IO_BASE) ($t0)
+	andi $t1, $t0, GRUB_CS5536_SMB_REG_STATUS_SDAST
+	bne $t1, $zero, return
+	 nop
+	andi $t1, $t0, (GRUB_CS5536_SMB_REG_STATUS_BER | GRUB_CS5536_SMB_REG_STATUS_NACK)
+	beq $t1, $zero, 1b
+	 nop
+	jr $a0
+	 nop
+return:
+	jr $ra
+	 nop
+	
+	/* Read SPD byte. In: $a0 byte, $a1 device. Out: $v0 read byte (0x100 on failure).
+           Clobbered: $t0, $t1, $t2, $t3, $a0. */
+read_spd:
+	move $t2, $a0
+	move $t3, $ra
+	lui $a0, %hi(read_spd_fail)
+	addiu $a0, $a0, %hi(read_spd_fail)
+
+	/* Send START.  */
+	lui $t0, %hi(GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_CTRL1 + GRUB_MACHINE_PCI_IO_BASE)
+	lb $t1, %lo(GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_CTRL1 + GRUB_MACHINE_PCI_IO_BASE) ($t0)
+	ori $t1, $t1, GRUB_CS5536_SMB_REG_CTRL1_START
+	bal smbus_wait
+	 sb $t1, %lo(GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_CTRL1 + GRUB_MACHINE_PCI_IO_BASE) ($t0)
+	
+	/* Send device address.  */
+	lui $t0, %hi(GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_DATA + GRUB_MACHINE_PCI_IO_BASE)
+	sll $t1, $a1, 1
+	bal smbus_wait
+	 sb $t1, %lo(GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_DATA + GRUB_MACHINE_PCI_IO_BASE) ($t0)
+
+	/* Send ACK.  */
+	lui $t0, %hi(GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_CTRL1 + GRUB_MACHINE_PCI_IO_BASE)
+	lb $t1, %lo(GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_CTRL1 + GRUB_MACHINE_PCI_IO_BASE) ($t0)
+	ori $t1, $t1, GRUB_CS5536_SMB_REG_CTRL1_ACK
+	sb $t1, %lo(GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_CTRL1 + GRUB_MACHINE_PCI_IO_BASE) ($t0)
+
+	/* Send byte address.  */
+	lui $t0, %hi(GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_DATA + GRUB_MACHINE_PCI_IO_BASE)
+	bal smbus_wait
+	 sb $t2, %lo(GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_DATA + GRUB_MACHINE_PCI_IO_BASE) ($t0)
+
+	/* Send START.  */
+	lui $t0, %hi(GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_CTRL1 + GRUB_MACHINE_PCI_IO_BASE)
+	lb $t1, %lo(GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_CTRL1 + GRUB_MACHINE_PCI_IO_BASE) ($t0)
+	ori $t1, $t1, GRUB_CS5536_SMB_REG_CTRL1_START
+	bal smbus_wait
+	 sb $t1, %lo(GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_CTRL1 + GRUB_MACHINE_PCI_IO_BASE) ($t0)
+
+	/* Send device address.  */
+	lui $t0, %hi(GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_DATA + GRUB_MACHINE_PCI_IO_BASE)
+	sll $t1, $a1, 1
+	ori $t1, $t1, 1
+	bal smbus_wait
+	 sb $t1, %lo(GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_DATA + GRUB_MACHINE_PCI_IO_BASE) ($t0)
+
+	/* Send STOP.  */
+	lui $t0, %hi(GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_CTRL1 + GRUB_MACHINE_PCI_IO_BASE)
+	lb $t1, %lo(GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_CTRL1 + GRUB_MACHINE_PCI_IO_BASE) ($t0)
+	ori $t1, $t1, GRUB_CS5536_SMB_REG_CTRL1_STOP
+	bal smbus_wait
+	 sb $t1, %lo(GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_CTRL1 + GRUB_MACHINE_PCI_IO_BASE) ($t0)
+
+	lui $t0, %hi(GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_DATA + GRUB_MACHINE_PCI_IO_BASE)
+	lb $v0, %lo(GRUB_CS5536_LBAR_SMBUS + GRUB_CS5536_SMB_REG_DATA + GRUB_MACHINE_PCI_IO_BASE) ($t0)
+	jr $t3
+	 andi $v0, $v0, 0xff
+read_spd_fail:
+	jr $t3
+	 ori $v0, $v0, 0x100
+
+notification_string:	.asciz "GRUB "
+no_cs5536:	.asciz "No CS5536 found.\n\r"
+cs5536_found:	.asciz "CS5536 at "
+sm_failed: .asciz "SM transaction failed.\n\r"
+unhandled_tlb_refill:	.asciz "Unhandled TLB refill.\n\r"
+unhandled_cache_error:	.asciz "Unhandled cache error.\n\r"
+unhandled_exception:	.asciz "Unhandled exception.\n\r"
+smbus_enabled:	.asciz "SMBus controller enabled.\n\r"
+unimplemented_memory_type:	.asciz "non-DDR2 memory isn't supported.\n\r"
+no_cas_latency:		.asciz "Couldn't determine CAS latency.\n\r"
+cause:	 .asciz "Cause: "
+epc:	.asciz "\n\rEPC: "
+badvaddr:	.asciz "\n\rBadVaddr: "
+newline:	.asciz "\n\r"
+return_msg:	  .asciz "\n\rReturn address: "
+caches_enabled:	.asciz "Caches enabled\n\r"
+
+	.p2align 3
+
+regdump:
+	.quad 0x0100010000000101 /* 0 */
+	.quad 0x0100010100000000 /* 2 */
+	.quad 0x0101000001000000 /* 3 */
+	.quad 0x0100020200010101 /* 4 */
+	.quad 0x0a04030603050203 /* 6 */
+	.quad 0x0f0e040000010a0b /* 7 */
+	.quad 0x0000010200000102 /* 8 */
+	.quad 0x0000060c00000000 /* 9 */
+	.quad 0x2323233f3f1f0200 /* a */
+	.quad 0x5f7f232323232323 /* b */
+	.quad 0x002a3c0615000000 /* c */
+	.quad 0x002a002a002a002a /* d */
+	.quad 0x002a002a002a002a /* e */
+	.quad 0x00b40020006d0004 /* f */
+	.quad 0x070007ff00000087 /* 10 */
+	.quad 0x000000000016101f /* 11 */
+	.quad 0x001c000000000000 /* 12 */
+	.quad 0x28e1000200c8006b /* 13 */
+	.quad 0x0000204200c8002f /* 14 */
+	.quad 0x0000000000030d40 /* 15 */
+	.quad 0 /* 16 */
+	.quad 0 /* 17 */
+	.quad 0 /* 18 */
+	.quad 0 /* 19 */
+	.quad 0 /* 1a */
+	.quad 0 /* 1b */
+	.quad 0 /* 1c */
+
+	.p2align
+
+write_dumpreg:	
+	ld $t2, 0($t6)
+	sd $t2, 0($t4)
+	addiu $t4, $t4, GRUB_CPU_LOONGSON_DDR2_REG_STEP
+	jr $ra
+	 addiu $t6, $t6, GRUB_CPU_LOONGSON_DDR2_REG_SIZE
+
+continue:
+	lui $t4, %hi(GRUB_CPU_LOONGSON_DDR2_BASE)
+	addiu $t4, $t4, %lo(GRUB_CPU_LOONGSON_DDR2_BASE)
+	lui $t6, %hi(regdump)
+
+	/* 0 */
+	bal write_dumpreg
+	 addiu $t6, $t6, %lo(regdump)
+
+	/* 1 */
+	ori $a1, $a1, GRUB_SMB_RAM_START_ADDR
+	move $t8, $zero
+	lui  $t5, 0x0001
+	bal read_spd
+	 ori $a0, $zero, GRUB_SMBUS_SPD_MEMORY_NUM_BANKS_ADDR
+	ori $t7, $zero, 8
+	bne $v0, $t7, 1f
+	 ori $t5, $t5, 0x0001
+	ori $t8, $t8, GRUB_CPU_LOONGSON_DDR2_REG1_HI_8BANKS
+1:
+	dsll $t8, $t8, 32
+	or $t5, $t5, $t8
+	sd  $t5, 0 ($t4)
+	addiu $t4, $t4, GRUB_CPU_LOONGSON_DDR2_REG_STEP
+
+	/* 2 */
+	bal write_dumpreg
+	 nop
+
+	/* 3 */
+	bal write_dumpreg
+	 nop
+
+	/* 4 */
+	bal write_dumpreg
+	 nop
+
+	/* 5 */
+	/* FIXME: figure termination resistance.  */
+	ori $t5, $zero, 0x2
+	bal read_spd
+	 ori $a0, $zero, GRUB_SMBUS_SPD_MEMORY_NUM_ROWS_ADDR
+	/* $v0 = 15 - $v0.  */
+	xori $v0, $v0, 0xf
+	andi $v0, $v0, 0x7
+	sll $v0, $v0, 8
+	or $t5, $t5, $v0
+
+	/* Find the fastest supported CAS latency.  */
+	bal read_spd
+	 ori $a0, $zero, GRUB_SMBUS_SPD_MEMORY_CAS_LATENCY_ADDR
+	ori $t0, $zero, GRUB_SMBUS_SPD_MEMORY_CAS_LATENCY_MIN_VALUE
+	ori $t1, $zero, (1 << GRUB_SMBUS_SPD_MEMORY_CAS_LATENCY_MIN_VALUE)
+2:	
+	and $t2, $t1, $v0
+	bne $t2, $zero, 1f
+	 ori $t3, $zero, 8
+	lui $a0, %hi(no_cas_latency)
+	beq $t0, $t3, fatal
+	 addiu $a0, $a0, %lo(no_cas_latency)
+	addiu $t0, $t0, 1
+	b 2b
+	 sll $t1, $t1, 1
+1:
+	sll $t0, $t0, 16
+	or $t5, $t5, $t0
+	
+	bal read_spd
+	 ori $a0, $zero, GRUB_SMBUS_SPD_MEMORY_NUM_COLUMNS_ADDR
+	/* $v0 = 15 - ($v0 + 1) = 14 - $v0.  */
+	addiu $v0, $v0, 1
+	xori $v0, $v0, 0xf
+	andi $v0, $v0, 0x7
+	sll $v0, 24
+	or $t5, $t5, $v0
+	sd  $t5, 0 ($t4)
+
+	addiu $t4, $t4, GRUB_CPU_LOONGSON_DDR2_REG_STEP
+	
+	ori $t7, $zero, 0x16
+
+1:	
+	ld $t2, 0($t6)
+	sd $t2, 0($t4)
+	addiu $t4, $t4, GRUB_CPU_LOONGSON_DDR2_REG_STEP
+	addiu $t7, $t7, -1
+	bne $t7, $zero, 1b
+	 addiu $t6, $t6, GRUB_CPU_LOONGSON_DDR2_REG_SIZE
+	
+	lui $t4, %hi(GRUB_CPU_LOONGSON_DDR2_BASE)
+	ld  $t5, (%lo(GRUB_CPU_LOONGSON_DDR2_BASE) + 0x30) ($t4)
+	ori $t0, $zero, 1
+	dsll $t0, $t0, 40
+	or $t5, $t5, $t0
+	sd  $t5, (%lo(GRUB_CPU_LOONGSON_DDR2_BASE) + 0x30) ($t4)
+
+	/* Desactivate DDR2 registers.  */
+        lui	$t0, %hi (GRUB_CPU_LOONGSON_CORECFG)
+        ld	$t1, %lo (GRUB_CPU_LOONGSON_CORECFG) ($t0)
+	ori	$t1, $t1, GRUB_CPU_LOONGSON_CORECFG_DISABLE_DDR2_SPACE
+        sd	$t1, %lo (GRUB_CPU_LOONGSON_CORECFG) ($t0)
+
+	/* Enable cache.  */
+	mfc0	$t0, GRUB_CPU_LOONGSON_COP0_CACHE_CONFIG
+	addiu 	$t1, $zero, ~GRUB_CPU_LOONGSON_CACHE_TYPE_MASK
+	and     $t0, $t1, $t1
+	/* Set line size to 32 bytes and disabled cache.  */
+	ori   	$t0, $t0, (GRUB_CPU_LOONGSON_COP0_CACHE_CONFIG_ILINESIZE \
+	                   | GRUB_CPU_LOONGSON_COP0_CACHE_CONFIG_DLINESIZE \
+	                   | GRUB_CPU_LOONGSON_CACHE_ACCELERATED)
+	mtc0	$t0, GRUB_CPU_LOONGSON_COP0_CACHE_CONFIG
+
+	/* Invalidate all I-cache entries.  */
+	srl $t1, $t0, GRUB_CPU_LOONGSON_COP0_CACHE_ISIZE_SHIFT
+	andi $t1, $t1, GRUB_CPU_LOONGSON_COP0_CACHE_SIZE_MASK
+	ori $t2, $zero, (1 << (GRUB_CPU_LOONGSON_COP0_CACHE_SIZE_OFFSET \
+	                       - GRUB_CPU_LOONGSON_CACHE_LINE_SIZE_LOG_BIG \
+	                       - GRUB_CPU_LOONGSON_I_CACHE_LOG_WAYS))
+	sll $t1, $t2, $t1
+	lui $t2, 0x8000
+
+1:	
+	cache GRUB_CPU_LOONGSON_COP0_I_INDEX_INVALIDATE, 0($t2)
+	addiu $t1, $t1, -1
+	bne $t1, $zero, 1b
+	 addiu $t2, $t2, (1 << GRUB_CPU_LOONGSON_COP0_I_INDEX_BIT_OFFSET)
+
+	/* Invalidate all D-cache entries.  */
+	srl $t1, $t0, GRUB_CPU_LOONGSON_COP0_CACHE_DSIZE_SHIFT
+	andi $t1, $t1, GRUB_CPU_LOONGSON_COP0_CACHE_SIZE_MASK
+	ori $t2, $zero, (1 << (GRUB_CPU_LOONGSON_COP0_CACHE_SIZE_OFFSET \
+	                       - GRUB_CPU_LOONGSON_CACHE_LINE_SIZE_LOG_BIG \
+	                       - GRUB_CPU_LOONGSON_D_CACHE_LOG_WAYS))
+	sll $t1, $t2, $t1
+	lui $t2, 0x8000
+	mtc0 $zero, GRUB_CPU_LOONGSON_COP0_CACHE_TAGLO
+	mtc0 $zero, GRUB_CPU_LOONGSON_COP0_CACHE_TAGHI
+1:
+	/* All four ways.  */
+	cache GRUB_CPU_LOONGSON_COP0_D_INDEX_TAG_STORE, 0($t2)
+	cache GRUB_CPU_LOONGSON_COP0_D_INDEX_TAG_STORE, 1($t2)
+	cache GRUB_CPU_LOONGSON_COP0_D_INDEX_TAG_STORE, 2($t2)
+	cache GRUB_CPU_LOONGSON_COP0_D_INDEX_TAG_STORE, 3($t2)
+	addiu $t1, $t1, -1
+	bne $t1, $zero, 1b
+	 addiu $t2, $t2, (1 << GRUB_CPU_LOONGSON_COP0_D_INDEX_BIT_OFFSET)
+
+	/* Invalidate all S-cache entries.  */
+	ori $t1, $zero, (1 << (GRUB_CPU_LOONGSON_SECONDARY_CACHE_LOG_SIZE \
+	                       - GRUB_CPU_LOONGSON_CACHE_LINE_SIZE_LOG_BIG \
+	                       - GRUB_CPU_LOONGSON_S_CACHE_LOG_WAYS))
+	lui $t2, 0x8000
+	mtc0 $zero, GRUB_CPU_LOONGSON_COP0_CACHE_TAGLO
+	mtc0 $zero, GRUB_CPU_LOONGSON_COP0_CACHE_TAGHI
+1:
+	/* All four ways.  */
+	cache GRUB_CPU_LOONGSON_COP0_S_INDEX_TAG_STORE, 0($t2)
+	cache GRUB_CPU_LOONGSON_COP0_S_INDEX_TAG_STORE, 1($t2)
+	cache GRUB_CPU_LOONGSON_COP0_S_INDEX_TAG_STORE, 2($t2)
+	cache GRUB_CPU_LOONGSON_COP0_S_INDEX_TAG_STORE, 3($t2)
+	addiu $t1, $t1, -1
+	bne $t1, $zero, 1b
+	 addiu $t2, $t2, (1 << GRUB_CPU_LOONGSON_COP0_D_INDEX_BIT_OFFSET)
+	
+	/* Finally enable cache.  */
+	mfc0	$t0, GRUB_CPU_LOONGSON_COP0_CACHE_CONFIG
+	addiu 	$t1, $zero, ~GRUB_CPU_LOONGSON_CACHE_TYPE_MASK
+	and     $t0, $t1, $t1
+	ori   	$t0, $t0, GRUB_CPU_LOONGSON_CACHE_CACHED
+	mtc0	$t0, GRUB_CPU_LOONGSON_COP0_CACHE_CONFIG
+
+	lui $a0, %hi(caches_enabled)
+	bal message
+	  addiu $a0, $a0, %lo(caches_enabled)
+
+	/* Set ROM delay cycles to 1.  */
+	lui $t0, %hi(GRUB_CPU_LOONGSON_LIOCFG)
+	lw  $t1, %lo(GRUB_CPU_LOONGSON_LIOCFG) ($t0)
+	addiu $t2, $zero, ~(GRUB_CPU_LOONGSON_ROM_DELAY_MASK \
+	                    << GRUB_CPU_LOONGSON_ROM_DELAY_OFFSET)
+	and $t1, $t1, $t2
+	ori $t1, $t1, (1 << GRUB_CPU_LOONGSON_ROM_DELAY_OFFSET)
+	sw  $t1, %lo(GRUB_CPU_LOONGSON_LIOCFG) ($t0)
+	
+	addiu $a0, $zero, -1
+	addiu $a1, $zero, -1
+
+	/* Take advantage of cache.  */
+	lui $t0, %hi(cached_continue - 0x20000000)
+	addiu $t0, $t0, %lo(cached_continue - 0x20000000)
+	jr $t0
+	 addiu $a2, $zero, -1
+
+cached_continue:
\ No newline at end of file
diff --git a/grub-core/boot/sparc64/ieee1275/boot.S b/grub-core/boot/sparc64/ieee1275/boot.S
new file mode 100644
index 0000000..f08258f
--- /dev/null
+++ b/grub-core/boot/sparc64/ieee1275/boot.S
@@ -0,0 +1,209 @@
+/* -*-Asm-*- */
+/*
+ *  GRUB  --  GRand Unified Bootloader
+ *  Copyright (C) 2009  Free Software Foundation, Inc.
+ *
+ *  GRUB is free software: you can redistribute it and/or modify
+ *  it under the terms of the GNU General Public License as published by
+ *  the Free Software Foundation, either version 3 of the License, or
+ *  (at your option) any later version.
+ *
+ *  GRUB is distributed in the hope that it will be useful,
+ *  but WITHOUT ANY WARRANTY; without even the implied warranty of
+ *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ *  GNU General Public License for more details.
+ *
+ *  You should have received a copy of the GNU General Public License
+ *  along with GRUB.  If not, see <http://www.gnu.org/licenses/>.
+ */
+
+#include <grub/boot.h>
+#include <grub/machine/boot.h>
+
+	.text
+	.align	4
+	.globl	_start
+_start:
+	/* OF CIF entry point arrives in %o4 */
+pic_base:
+	call	boot_continue
+	 mov	%o4, CIF_REG
+
+	. = _start + GRUB_BOOT_MACHINE_VER_MAJ
+boot_version:		.byte	GRUB_BOOT_VERSION_MAJOR, GRUB_BOOT_VERSION_MINOR
+
+	/* The offsets to these locations are defined by the
+	 * GRUB_BOOT_MACHINE_foo macros in include/grub/sparc/ieee1275/boot.h,
+	 * and grub-setup uses this to patch these next three values as needed.
+	 *
+	 * The boot_path will be the OF device path of the partition where the
+	 * rest of the GRUB kernel image resides.  kernel_sector will be set to
+	 * the location of the first block of the GRUB kernel, and
+	 * kernel_address is the location where we should load that first block.
+	 *
+	 * After loading in that block we will execute it by jumping to the
+	 * load address plus the size of the prepended A.OUT header (32 bytes).
+	 */
+boot_path:
+	. = _start + GRUB_BOOT_MACHINE_KERNEL_BYTE
+boot_path_end:
+kernel_byte:		.xword (2 << 9)
+kernel_address:		.word  GRUB_BOOT_MACHINE_KERNEL_ADDR
+
+prom_finddev_name:	.asciz "finddevice"
+prom_chosen_path:	.asciz "/chosen"
+prom_getprop_name:	.asciz "getprop"
+prom_stdout_name:	.asciz "stdout"
+prom_write_name:	.asciz "write"
+prom_bootpath_name:	.asciz "bootpath"
+prom_open_name:		.asciz "open"
+prom_seek_name:		.asciz "seek"
+prom_read_name:		.asciz "read"
+prom_exit_name:		.asciz "exit"
+grub_name:		.asciz "GRUB "
+#define GRUB_NAME_LEN	5
+
+	.align	4
+
+prom_open_error:
+	GET_ABS(prom_open_name, %o2)
+	call	console_write
+	 mov	4, %o3
+	/* fallthru */
+
+prom_error:
+	GET_ABS(prom_exit_name, %o0)
+	/* fallthru */
+
+	/* %o0: OF call name
+	 * %o1: input arg 1
+	 */
+prom_call_1_1_o2:
+	clr	%o2
+	ba	prom_call_x_1
+	 mov	1, %g1
+
+prom_call_getprop:
+	mov	4, %g1
+	stx	%g1, [%l1 + 256]
+	mov	CHOSEN_NODE_REG, %o1
+	ba	prom_call_x_1
+	 GET_ABS(prom_getprop_name, %o0)
+
+prom_call_3_1_o1:
+	ba prom_call_3_1
+	 mov	BOOTDEV_REG, %o1
+
+	
+	/* %o2: message string
+	 * %o3: message length
+	 */
+console_write:
+	GET_ABS(prom_write_name, %o0)
+	mov	STDOUT_NODE_REG, %o1
+	/* fallthru */
+
+	/* %o0: OF call name
+	 * %o1: input arg 1
+	 * %o2: input arg 2
+	 * %o3: input arg 3
+	 */
+prom_call_3_1:	
+	mov	3, %g1
+prom_call_x_1:
+	mov	1, %o5
+	/* fallthru */
+
+	/* %o0: OF call name
+	 * %g1: num inputs
+	 * %o5: num outputs
+	 * %o1-%o4: inputs
+	 */
+prom_call:
+	stx	%o0, [%l1 + 0x00]
+	stx	%g1, [%l1 + 0x08]
+	stx	%o5, [%l1 + 0x10]
+	stx	%o1, [%l1 + 0x18]
+	stx	%o2, [%l1 + 0x20]
+	stx	%o3, [%l1 + 0x28]
+	stx	%o4, [%l1 + 0x30]
+	jmpl	CIF_REG, %g0
+	 mov	%l1, %o0
+
+boot_continue:
+	mov	%o7, PIC_REG		/* PIC base */
+	sethi	%hi(SCRATCH_PAD_BOOT), %l1	/* OF argument slots */
+
+	/* Find the /chosen node so we can fetch the stdout handle,
+	 * and thus perform console output.
+	 *
+	 * chosen_node = prom_finddevice("/chosen")
+	 */
+	GET_ABS(prom_finddev_name, %o0)
+	call	prom_call_1_1_o2
+	 GET_ABS(prom_chosen_path, %o1)
+
+	ldx	[%l1 + 0x20], CHOSEN_NODE_REG
+	brz	CHOSEN_NODE_REG, prom_error
+
+	/* getprop(chosen_node, "stdout", &buffer, buffer_size) */
+	 GET_ABS(prom_stdout_name, %o2)
+	add	%l1, 256, %o3
+	call	prom_call_getprop
+	 mov	1024, %o4
+
+	lduw	[%l1 + 256], STDOUT_NODE_REG
+	brz,pn	STDOUT_NODE_REG, prom_error
+
+	/* write(stdout_node, "GRUB ", strlen("GRUB ")) */
+	 GET_ABS(grub_name, %o2)
+	call	console_write
+	 mov	GRUB_NAME_LEN, %o3
+
+	GET_ABS(boot_path, %o3)
+	ldub	[%o3], %o1
+	brnz,pn	%o1, bootpath_known
+
+	/* getprop(chosen_node, "bootpath", &buffer, buffer_size) */
+	 GET_ABS(prom_bootpath_name, %o2)
+	call	prom_call_getprop
+	 mov	(boot_path_end - boot_path), %o4
+
+bootpath_known:	
+
+	/* Open up the boot_path, and use that handle to read the
+	 * first block of the GRUB kernel image.
+	 *
+	 * bootdev_handle = open(boot_path)
+	 */
+	GET_ABS(prom_open_name, %o0)
+	call	prom_call_1_1_o2
+	 GET_ABS(boot_path, %o1)
+
+	ldx	[%l1 + 0x20], BOOTDEV_REG
+	brz,pn	BOOTDEV_REG, prom_open_error
+
+	/* Since we have 64-bit cells, the high cell of the seek offset
+	 * is zero and the low cell is the entire value.
+	 *
+	 * seek(bootdev, 0, *kernel_byte)
+	 */
+	 GET_ABS(prom_seek_name, %o0)
+	clr	%o2
+	call	prom_call_3_1_o1
+	 LDX_ABS(kernel_byte, 0x00, %o3)
+
+	/* read(bootdev, *kernel_address, 512) */
+	GET_ABS(prom_read_name, %o0)
+	LDUW_ABS(kernel_address, 0x00, %o2)
+	call	prom_call_3_1_o1
+	 mov	512, %o3
+
+	LDUW_ABS(kernel_address, 0x00, %o2)
+	jmpl	%o2, %o7
+	 nop
+
+	. = _start + GRUB_BOOT_MACHINE_CODE_END
+
+/* the last 4 bytes in the sector 0 contain the signature */
+	.word	GRUB_BOOT_MACHINE_SIGNATURE
diff --git a/grub-core/boot/sparc64/ieee1275/diskboot.S b/grub-core/boot/sparc64/ieee1275/diskboot.S
new file mode 100644
index 0000000..83dfee0
--- /dev/null
+++ b/grub-core/boot/sparc64/ieee1275/diskboot.S
@@ -0,0 +1,146 @@
+/* -*-Asm-*- */
+/*
+ *  GRUB  --  GRand Unified Bootloader
+ *  Copyright (C) 2009  Free Software Foundation, Inc.
+ *
+ *  GRUB is free software: you can redistribute it and/or modify
+ *  it under the terms of the GNU General Public License as published by
+ *  the Free Software Foundation, either version 3 of the License, or
+ *  (at your option) any later version.
+ *
+ *  GRUB is distributed in the hope that it will be useful,
+ *  but WITHOUT ANY WARRANTY; without even the implied warranty of
+ *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ *  GNU General Public License for more details.
+ *
+ *  You should have received a copy of the GNU General Public License
+ *  along with GRUB.  If not, see <http://www.gnu.org/licenses/>.
+ */
+
+#include <grub/boot.h>
+#include <grub/machine/boot.h>
+#include <grub/offsets.h>
+
+	.text
+	.align	4
+	.globl	_start
+_start:
+	/* First stage boot block jumps to us here.  */
+pic_base:
+	call	after_info_block
+	 mov	%o7, PIC_REG
+
+prom_write_name:		.asciz "write"
+prom_seek_name:			.asciz "seek"
+prom_read_name:			.asciz "read"
+prom_close_name:		.asciz "close"
+
+notification_string:		.asciz "Loading kernel"
+#define NOTIFICATION_STRING_LEN	14
+
+notification_step:		.asciz "."
+#define NOTIFICATION_STEP_LEN	1
+
+notification_done:		.asciz "\r\n"
+#define NOTIFICATION_DONE_LEN	2
+
+	.align	4
+
+	/* %o2: message string
+	 * %o3: message length
+	 */
+console_write:
+	GET_ABS(prom_write_name, %o0)
+	mov	STDOUT_NODE_REG, %o1
+	/* fallthru */
+
+	/* %o0: OF call name
+	 * %o1: input arg 1
+	 * %o2: input arg 2
+	 * %o3: input arg 3
+	 */
+prom_call_3_1:
+	mov	3, %g1
+	mov	1, %o5
+	/* fallthru */
+
+	/* %o0: OF call name
+	 * %g1: num inputs
+	 * %o5: num outputs
+	 * %o1-%o4: inputs
+	 */
+prom_call:
+	stx	%o0, [%l1 + 0x00]
+	stx	%g1, [%l1 + 0x08]
+	stx	%o5, [%l1 + 0x10]
+	stx	%o1, [%l1 + 0x18]
+	stx	%o2, [%l1 + 0x20]
+	stx	%o3, [%l1 + 0x28]
+	stx	%o4, [%l1 + 0x30]
+	jmpl	CIF_REG, %g0
+	 mov	%l1, %o0
+
+
+after_info_block:
+	sethi	%hi(SCRATCH_PAD_DISKBOOT), %l1	/* OF argument slots */
+
+	GET_ABS(notification_string, %o2)
+	call	console_write
+	 mov	NOTIFICATION_STRING_LEN, %o3
+
+	GET_ABS(firstlist - GRUB_BOOT_SPARC64_IEEE1275_LIST_SIZE, %l2)
+	set	GRUB_BOOT_SPARC64_IEEE1275_IMAGE_ADDRESS, %l3
+bootloop:
+	lduw	[%l2 + 0x08], %o0
+	brz	%o0, bootit
+	 lduw	[%l2 + 0x00], %o3
+	sllx	%o3, 32, %o3
+	lduw	[%l2 + 0x04], %o4
+	or	%o3, %o4, %o3
+	GET_ABS(prom_seek_name, %o0)
+	mov	BOOTDEV_REG, %o1
+	clr	%o2
+	call	prom_call_3_1
+	 sllx	%o3, 9, %o3
+
+	GET_ABS(prom_read_name, %o0)
+	mov	BOOTDEV_REG, %o1
+	lduw	[%l2 + 0x08], %o3
+	sllx	%o3, 9, %o3
+	mov	%l3, %o2
+	call	prom_call_3_1
+	 add	%l3, %o3, %l3
+
+	GET_ABS(notification_step, %o2)
+	call	console_write
+	 mov	NOTIFICATION_STEP_LEN, %o3
+
+	ba	bootloop
+	 sub	%l2, GRUB_BOOT_SPARC64_IEEE1275_LIST_SIZE, %l2
+
+bootit:
+	GET_ABS(prom_close_name, %o0)
+	mov	1, %g1
+	mov	0, %o5
+	call	prom_call
+	 mov	BOOTDEV_REG, %o1
+
+	GET_ABS(notification_done, %o2)
+	call	console_write
+	 mov	NOTIFICATION_DONE_LEN, %o3
+	sethi	%hi(GRUB_BOOT_SPARC64_IEEE1275_IMAGE_ADDRESS), %o2
+	jmpl	%o2 + %lo(GRUB_BOOT_SPARC64_IEEE1275_IMAGE_ADDRESS), %o7
+	 mov	CIF_REG, %o4
+1:	ba,a	1b
+
+lastlist:
+	.word	0
+	.word	0
+
+	. = _start + (0x200 - GRUB_BOOT_SPARC64_IEEE1275_LIST_SIZE)
+blocklist_default_start:
+	.word	0
+	.word	2
+blocklist_default_len:
+	.word	0
+firstlist: