1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
|
library ieee ;
use ieee.std_logic_1164.all ;
library std ;
use std.textio.all ;
entity match_operators is
end entity match_operators ;
architecture arch of match_operators is
-- Index is (L,R)
type result_table_t is array(std_ulogic, std_ulogic) of std_ulogic ;
function "not"(x : result_table_t) return result_table_t is
variable rv : result_table_t := (others =>(others =>'-'));
begin
for l in x'range(1) loop
for r in x'range(2) loop
rv(l, r) := not x(l,r) ;
end loop ;
end loop ;
return rv ;
end function ;
function "or"(a, b : result_table_t) return result_table_t is
variable rv : result_table_t := (others =>(others =>'-'));
begin
for l in std_ulogic loop
for r in std_ulogic loop
rv(l,r) := a(l,r) or b(l,r) ;
end loop ;
end loop ;
return rv ;
end function ;
procedure print_table(name : string ; x : result_table_t) is
variable currentline : line ;
begin
write(currentline, "Table: " & name) ;
writeline(output, currentline) ;
writeline(output, currentline) ;
-- Header
write(currentline, string'("L\R|")) ;
for idx in x'range(2) loop
write(currentline, std_ulogic'image(idx) & ' ') ;
end loop ;
writeline(output, currentline) ;
write(currentline, string'("---+")) ;
for idx in x'range(2) loop
if idx /= std_ulogic'right then
write(currentline, string'("----")) ;
else
write(currentline, string'("---")) ;
end if ;
end loop ;
writeline(output, currentline) ;
for l in x'range(1) loop
for r in x'range(2) loop
if r = std_ulogic'left then
write(currentline, std_ulogic'image(l) & '|' ) ;
end if ;
write(currentline, std_ulogic'image(x(l, r)) & ' ') ;
end loop ;
writeline(output, currentline) ;
end loop ;
writeline(output, currentline) ;
end procedure ;
constant equal_table : result_table_t := (
-- U X 0 1 Z W L H -
('U','U','U','U','U','U','U','U','1'), -- 'U'
('U','X','X','X','X','X','X','X','1'), -- 'X'
('U','X','1','0','X','X','1','0','1'), -- '0'
('U','X','0','1','X','X','0','1','1'), -- '1'
('U','X','X','X','X','X','X','X','1'), -- 'Z'
('U','X','X','X','X','X','X','X','1'), -- 'W'
('U','X','1','0','X','X','1','0','1'), -- 'L'
('U','X','0','1','X','X','0','1','1'), -- 'H'
('1','1','1','1','1','1','1','1','1') -- '-'
) ;
constant less_table : result_table_t := (
-- U X 0 1 Z W L H -
('U','U','U','U','U','U','U','U','X'), -- 'U'
('U','X','X','X','X','X','X','X','X'), -- 'X'
('U','X','0','1','X','X','0','1','X'), -- '0'
('U','X','0','0','X','X','0','0','X'), -- '1'
('U','X','X','X','X','X','X','X','X'), -- 'Z'
('U','X','X','X','X','X','X','X','X'), -- 'W'
('U','X','0','1','X','X','0','1','X'), -- 'L'
('U','X','0','0','X','X','0','0','X'), -- 'H'
('X','X','X','X','X','X','X','X','X') -- '-'
) ;
constant inequal_table : result_table_t := not equal_table ;
constant less_equal_table : result_table_t := equal_table or less_table ;
constant greater_equal_table : result_table_t := not less_table ;
constant greater_table : result_table_t := not less_equal_table ;
begin
tb : process
variable y : std_ulogic ;
variable check : std_ulogic ;
begin
-- Print the tables out
print_table("?=", equal_table) ;
print_table("?/=", inequal_table) ;
print_table("?<", less_table) ;
print_table("?<=", less_equal_table) ;
print_table("?>=", greater_equal_table) ;
print_table("?>", greater_table) ;
for l in std_ulogic loop
for r in std_ulogic loop
-- Match Equality
y := l ?= r ;
check := equal_table(l, r) ;
assert(y = check) report
std_ulogic'image(l) & " ?= " & std_ulogic'image(r) & " expected: " & std_ulogic'image(check) & " got: " & std_ulogic'image(y)
severity failure ;
-- Match Inequality
y := l ?/= r ;
check := inequal_table(l, r) ;
assert(y = check) report
std_ulogic'image(l) & " ?/= " & std_ulogic'image(r) & " expected: " & std_ulogic'image(check) & " got: " & std_ulogic'image(y)
severity failure ;
-- Match Less
y := l ?< r ;
check := less_table(l, r) ;
assert(y = check) report
std_ulogic'image(l) & " ?< " & std_ulogic'image(r) & " expected: " & std_ulogic'image(check) & " got: " & std_ulogic'image(y)
severity failure ;
-- Match Less Equal
y := l ?<= r ;
check := less_equal_table(l, r) ;
assert(y = check) report
std_ulogic'image(l) & " ?<= " & std_ulogic'image(r) & " expected: " & std_ulogic'image(check) & " got: " & std_ulogic'image(y)
severity failure ;
-- Match Greater Equal
y := l ?>= r ;
check := greater_equal_table(l, r) ;
assert(y = check) report
std_ulogic'image(l) & " ?>= " & std_ulogic'image(r) & " expected: " & std_ulogic'image(check) & " got: " & std_ulogic'image(y)
severity failure ;
-- Match Greater
y := l ?> r ;
check := greater_table(l, r) ;
assert(y = check) report
std_ulogic'image(l) & " ?> " & std_ulogic'image(r) & " expected: " & std_ulogic'image(check) & " got: " & std_ulogic'image(y)
severity failure ;
end loop ;
end loop ;
wait ;
end process ;
end architecture arch ;
|