1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
|
-- GHDL Run Time (GRT) - secondary stack.
-- Copyright (C) 2002 - 2014 Tristan Gingold
--
-- This program is free software: you can redistribute it and/or modify
-- it under the terms of the GNU General Public License as published by
-- the Free Software Foundation, either version 2 of the License, or
-- (at your option) any later version.
--
-- This program is distributed in the hope that it will be useful,
-- but WITHOUT ANY WARRANTY; without even the implied warranty of
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
-- GNU General Public License for more details.
--
-- You should have received a copy of the GNU General Public License
-- along with this program. If not, see <gnu.org/licenses>.
--
-- As a special exception, if other files instantiate generics from this
-- unit, or you link this unit with other files to produce an executable,
-- this unit does not by itself cause the resulting executable to be
-- covered by the GNU General Public License. This exception does not
-- however invalidate any other reasons why the executable file might be
-- covered by the GNU Public License.
with Ada.Unchecked_Conversion;
with Ada.Unchecked_Deallocation;
with Grt.Stdio;
with Grt.Astdio;
package body Grt.Stack2 is
-- This should be storage_elements.storage_element, but I don't want to
-- use system.storage_elements package (not pure). Unfortunatly, this is
-- currently a failure (storage_elements is automagically used).
type Memory is array (Mark_Id range <>) of Character;
-- Minimal chunk size. Avoid to allocate too many small chunks.
Min_Chunk_Size : constant Mark_Id := 8 * 1024;
type Chunk_Type (First, Last : Mark_Id);
type Chunk_Acc is access all Chunk_Type;
type Chunk_Type (First, Last : Mark_Id) is record
Next : Chunk_Acc;
Mem : Memory (First .. Last);
end record;
type Stack2_Type is record
First_Chunk : Chunk_Acc;
Last_Chunk : Chunk_Acc;
-- Index of the first free byte.
Top : Mark_Id;
end record;
type Stack2_Acc is access all Stack2_Type;
function To_Acc is new Ada.Unchecked_Conversion
(Source => Stack2_Ptr, Target => Stack2_Acc);
function To_Addr is new Ada.Unchecked_Conversion
(Source => Stack2_Acc, Target => Stack2_Ptr);
procedure Free is new Ada.Unchecked_Deallocation
(Object => Chunk_Type, Name => Chunk_Acc);
function Mark (S : Stack2_Ptr) return Mark_Id
is
S2 : constant Stack2_Acc := To_Acc (S);
begin
return S2.Top;
end Mark;
procedure Release (S : Stack2_Ptr; Mark : Mark_Id)
is
S2 : constant Stack2_Acc := To_Acc (S);
begin
S2.Top := Mark;
end Release;
function Allocate (S : Stack2_Ptr; Size : Ghdl_Index_Type)
return System.Address
is
pragma Suppress (All_Checks);
S2 : constant Stack2_Acc := To_Acc (S);
Chunk : Chunk_Acc;
N_Chunk : Chunk_Acc;
L_Chunk : Chunk_Acc;
Max_Align : constant Mark_Id := Mark_Id (Standard'Maximum_Alignment);
Aligned_Size : constant Mark_Id :=
((Mark_Id (Size) + Max_Align - 1) / Max_Align) * Max_Align;
Res : System.Address;
begin
-- Find the chunk to which S2.TOP belong.
-- FIXME: save an hint to that value ?
Chunk := S2.First_Chunk;
loop
exit when S2.Top >= Chunk.First and S2.Top <= Chunk.Last;
Chunk := Chunk.Next;
exit when Chunk = null;
end loop;
if Chunk /= null then
-- If there is enough place in it, allocate from the chunk.
if Aligned_Size <= Chunk.Last - S2.Top + 1 then
Res := Chunk.Mem (S2.Top)'Address;
S2.Top := S2.Top + Aligned_Size;
return Res;
end if;
-- If there is not enough place in it: try the next one. If not
-- enough room, free it and all the following chunks.
L_Chunk := Chunk;
Chunk := Chunk.Next;
if Chunk /= null then
if Aligned_Size <= Chunk.Last - Chunk.First + 1 then
Res := Chunk.Mem (Chunk.First)'Address;
S2.Top := Chunk.First + Aligned_Size;
return Res;
else
-- Free Chunk and all the following ones. Do not forget to
-- update Last_Chunk.
S2.Last_Chunk := L_Chunk;
loop
N_Chunk := Chunk.Next;
Free (Chunk);
Chunk := N_Chunk;
exit when Chunk = null;
end loop;
end if;
end if;
end if;
-- If not such chunk, allocate a chunk
S2.Top := S2.Last_Chunk.Last + 1;
Chunk := new Chunk_Type
(First => S2.Top,
Last => S2.Top + Mark_Id'Max (Aligned_Size, Min_Chunk_Size) - 1);
Chunk.Next := null;
S2.Last_Chunk.Next := Chunk;
S2.Last_Chunk := Chunk;
S2.Top := Chunk.Last + 1;
return Chunk.Mem (Chunk.First)'Address;
end Allocate;
function Create return Stack2_Ptr
is
Res : Stack2_Acc;
Chunk : Chunk_Acc;
begin
Chunk := new Chunk_Type (First => 1, Last => Min_Chunk_Size);
Chunk.Next := null;
Res := new Stack2_Type'(First_Chunk => Chunk,
Last_Chunk => Chunk,
Top => 1);
return To_Addr (Res);
end Create;
function Is_Empty (S : Stack2_Ptr) return Boolean
is
S2 : constant Stack2_Acc := To_Acc (S);
begin
if S2 = null then
return True;
end if;
return S2.Top = 1;
end Is_Empty;
procedure Dump_Stack2 (S : Stack2_Ptr)
is
use Grt.Astdio;
use Grt.Stdio;
use System;
function To_Address is new Ada.Unchecked_Conversion
(Source => Chunk_Acc, Target => Address);
function To_Address is new Ada.Unchecked_Conversion
(Source => Mark_Id, Target => Address);
S2 : Stack2_Acc;
Chunk : Chunk_Acc;
begin
S2 := To_Acc (S);
Put ("Stack 2 at ");
Put (stdout, Address (S));
New_Line;
if S2 = null then
return;
end if;
Put ("First Chunk at ");
Put (stdout, To_Address (S2.First_Chunk));
Put (", last chunk at ");
Put (stdout, To_Address (S2.Last_Chunk));
Put (", top at ");
Put (stdout, To_Address (S2.Top));
New_Line;
Chunk := S2.First_Chunk;
while Chunk /= null loop
Put ("Chunk ");
Put (stdout, To_Address (Chunk));
Put (": first: ");
Put (stdout, To_Address (Chunk.First));
Put (", last: ");
Put (stdout, To_Address (Chunk.Last));
Put (", len: ");
Put (stdout, To_Address (Chunk.Last - Chunk.First + 1));
Put (", next = ");
Put (stdout, To_Address (Chunk.Next));
New_Line;
Chunk := Chunk.Next;
end loop;
end Dump_Stack2;
end Grt.Stack2;
|
