buildscript {
    repositories {
        mavenCentral()
    }

    dependencies {
        // NOTE: Avoid using dynamic versions (+). This breaks offline builds!
        classpath 'com.android.tools.build:gradle:0.6.3'
    }
}

apply plugin: 'android'

repositories {
    mavenCentral()
}

/*
 * NOTE: Avoid dependencies from Maven. Include as much sources as possible for F-Droid!
 */
dependencies {
    compile fileTree(dir: 'libs', includes: ['*.jar'], excludes: ['android-support-v4.jar'])
    compile 'com.android.support:support-v4:18.0.+' // already in actionbarsherlock
    compile project(':libraries:ActionBarSherlock')
    compile project(':libraries:HtmlTextView')
    compile project(':libraries:StickyListHeaders:library')
    compile project(':libraries:zxing')
    compile project(':libraries:AndroidBootstrap')
}

android {
    compileSdkVersion 19
    buildToolsVersion "19"

    defaultConfig {
        minSdkVersion 8
        targetSdkVersion 19
    }

    sourceSets {
        main {
            manifest.srcFile 'AndroidManifest.xml'
            java.srcDirs = ['src']
            resources.srcDirs = ['src']
            aidl.srcDirs = ['src']
            renderscript.srcDirs = ['src']
            res.srcDirs = ['res']
            assets.srcDirs = ['assets']
        }

        instrumentTest.setRoot('tests')
    }

    /*
     * To sign release build, create file gradle.properties in ~/.gradle/ with this content:
     *
     * signingStoreLocation=/home/key.store
     * signingStorePassword=xxx
     * signingKeyAlias=alias
     * signingKeyPassword=xxx
     */
    if (project.hasProperty('signingStoreLocation') &&
            project.hasProperty('signingStorePassword') &&
            project.hasProperty('signingKeyAlias') &&
            project.hasProperty('signingKeyPassword')) {
        println "Found sign properties in gradle.properties! Signing build…"
        
        signingConfigs {
            release {
                storeFile file(signingStoreLocation)
                storePassword signingStorePassword
                keyAlias signingKeyAlias
                keyPassword signingKeyPassword
            }
        }

        buildTypes.release.signingConfig = signingConfigs.release
    } else {
        buildTypes.release.signingConfig = null
    }
}