From 9c9ca16e05456fd52e9061a541ab6c4f62f489aa Mon Sep 17 00:00:00 2001
From: gdisirio <gdisirio@35acf78f-673a-0410-8e92-d51de3d6d3f4>
Date: Mon, 8 Aug 2011 07:50:54 +0000
Subject: git-svn-id: svn://svn.code.sf.net/p/chibios/svn/trunk@3208
 35acf78f-673a-0410-8e92-d51de3d6d3f4

---
 os/ports/GCC/ARM/LPC214x/ld/LPC2148.ld | 107 +++++++++++++++++++++++++++++++++
 os/ports/GCC/ARM/LPC214x/port.mk       |  13 ++++
 os/ports/GCC/ARM/port.mk               |   7 ---
 3 files changed, 120 insertions(+), 7 deletions(-)
 create mode 100644 os/ports/GCC/ARM/LPC214x/ld/LPC2148.ld
 create mode 100644 os/ports/GCC/ARM/LPC214x/port.mk
 delete mode 100644 os/ports/GCC/ARM/port.mk

(limited to 'os/ports')

diff --git a/os/ports/GCC/ARM/LPC214x/ld/LPC2148.ld b/os/ports/GCC/ARM/LPC214x/ld/LPC2148.ld
new file mode 100644
index 000000000..40683d14e
--- /dev/null
+++ b/os/ports/GCC/ARM/LPC214x/ld/LPC2148.ld
@@ -0,0 +1,107 @@
+/*
+    ChibiOS/RT - Copyright (C) 2006,2007,2008,2009,2010,
+                 2011 Giovanni Di Sirio.
+
+    This file is part of ChibiOS/RT.
+
+    ChibiOS/RT is free software; you can redistribute it and/or modify
+    it under the terms of the GNU General Public License as published by
+    the Free Software Foundation; either version 3 of the License, or
+    (at your option) any later version.
+
+    ChibiOS/RT is distributed in the hope that it will be useful,
+    but WITHOUT ANY WARRANTY; without even the implied warranty of
+    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+    GNU General Public License for more details.
+
+    You should have received a copy of the GNU General Public License
+    along with this program.  If not, see <http://www.gnu.org/licenses/>.
+*/
+
+/*
+ * LPC2148 memory setup.
+ */
+__und_stack_size__	= 0x0004;
+__abt_stack_size__	= 0x0004;
+__fiq_stack_size__	= 0x0010;
+__irq_stack_size__	= 0x0080;
+__svc_stack_size__	= 0x0004;
+__sys_stack_size__	= 0x0400;
+__stacks_total_size__	= __und_stack_size__ + __abt_stack_size__ + __fiq_stack_size__ + __irq_stack_size__ + __svc_stack_size__ + __sys_stack_size__;
+
+MEMORY
+{
+    flash : org = 0x00000000, len = 512k - 12k
+    ram : org = 0x40000200, len = 32k - 0x200 - 288
+}
+
+__ram_start__       = ORIGIN(ram);
+__ram_size__        = LENGTH(ram);
+__ram_end__         = __ram_start__ + __ram_size__;
+__dma_start__       = 0x7FD00000;
+__dma_size__        = 8k;
+__dma_end__         = 0x7FD00000 + __dma_size__;
+
+SECTIONS
+{
+    . = 0;
+
+    .text : ALIGN(16) SUBALIGN(16)
+    {
+        _text = .;
+        KEEP(*(vectors))
+        *(.text)
+        *(.text.*)
+        *(.rodata)
+        *(.rodata.*)
+        *(.glue_7t)
+        *(.glue_7)
+        *(.gcc*)
+        *(.ctors)
+        *(.dtors)
+    } > flash
+
+    .ARM.extab : {*(.ARM.extab* .gnu.linkonce.armextab.*)}
+
+    __exidx_start = .;
+    .ARM.exidx : {*(.ARM.exidx* .gnu.linkonce.armexidx.*)} > flash
+    __exidx_end = .;
+
+    .eh_frame_hdr : {*(.eh_frame_hdr)}
+
+    .eh_frame : ONLY_IF_RO {*(.eh_frame)}
+
+    . = ALIGN(4);
+    _etext = .;
+    _textdata = _etext;
+
+    .data :
+    {
+        _data = .;
+        *(.data)
+        . = ALIGN(4);
+        *(.data.*)
+        . = ALIGN(4);
+        *(.ramtext)
+        . = ALIGN(4);
+        _edata = .;
+    } > ram AT > flash
+
+    .bss :
+    {
+        _bss_start = .;
+        *(.bss)
+        . = ALIGN(4);
+        *(.bss.*)
+        . = ALIGN(4);
+        *(COMMON)
+        . = ALIGN(4);
+        _bss_end = .;
+    } > ram    
+}
+
+PROVIDE(end = .);
+_end =			.;
+
+__heap_base__		= _end;
+__heap_end__		= __ram_end__ - __stacks_total_size__;
diff --git a/os/ports/GCC/ARM/LPC214x/port.mk b/os/ports/GCC/ARM/LPC214x/port.mk
new file mode 100644
index 000000000..1fcd858e5
--- /dev/null
+++ b/os/ports/GCC/ARM/LPC214x/port.mk
@@ -0,0 +1,13 @@
+# List of the ChibiOS/RT ARM7 LPC214x port files.
+PORTSRC = ${CHIBIOS}/os/ports/GCC/ARM/chcore.c
+
+PORTASM = ${CHIBIOS}/os/ports/GCC/ARM/crt0.s \
+          ${CHIBIOS}/os/ports/GCC/ARM/chcoreasm.s \
+          ${CHIBIOS}/os/ports/GCC/ARM/LPC214x/vectors.s
+
+
+PORTINC = ${CHIBIOS}/os/ports/GCC/ARM \
+          ${CHIBIOS}/os/ports/GCC/ARM/LPC214x
+
+PORTLD  = ${CHIBIOS}/os/ports/GCC/ARM/LPC214x/ld
+
diff --git a/os/ports/GCC/ARM/port.mk b/os/ports/GCC/ARM/port.mk
deleted file mode 100644
index fdad5f5e6..000000000
--- a/os/ports/GCC/ARM/port.mk
+++ /dev/null
@@ -1,7 +0,0 @@
-# List of the ChibiOS/RT ARM7/9 port files.
-PORTSRC = ${CHIBIOS}/os/ports/GCC/ARM/chcore.c
-
-PORTASM = ${CHIBIOS}/os/ports/GCC/ARM/crt0.s \
-          ${CHIBIOS}/os/ports/GCC/ARM/chcoreasm.s
-
-PORTINC = ${CHIBIOS}/os/ports/GCC/ARM
-- 
cgit v1.2.3